Save as dialog box defaulted to XLSM

[tonywatsonhelp]

Hi Everyone,
I'd like a macro that when i run it it opens the save as dialog box and defaults to XLSM

the file name is in activesheet "D17" and is written as just the name so "Tony Test1" for example,
so i'd like the dialog box to have "Tony Test 1" in the save as name area and XLSM but everything I try give me XLSX
some of the file are being converted from XLSX to XLSM please help if you can.

I've attached the code I use, but feel free to give me your own if you wish

Heres my code:

Sub SaveAs1()
    Dim ws As Worksheet
    Dim fileName As String
    Dim saveAsDialog As FileDialog
    Dim savePath As Variant

    Set ws = ThisWorkbook.ActiveSheet

    fileName = ws.Range("F17").Value

    Set saveAsDialog = Application.FileDialog(msoFileDialogSaveAs)
 
    saveAsDialog.Title = "Please choose location to save this document"
    
        If InStrRev(fileName, ".xlsm") = 0 Then
        fileName = fileName & ".xlsm"
        End If
    
    saveAsDialog.InitialFileName = fileName

    If saveAsDialog.Show = -1 Then

        savePath = saveAsDialog.SelectedItems(1)
        ThisWorkbook.SaveAs fileName:=savePath
        MsgBox "Document has been saved"
        ws.Range("D19").Value = "Saved"
        
        
       Call RoleM_show
       MsgBox "You can now start building the Role Matrix data.", , ""
        
    Else

        MsgBox "Document not saved!"
    End If
End Sub

 

[MARK858]

Maybe...

Application.Dialogs(xlDialogSaveAs).Show "Tony Test1", 52

 

[tonywatsonhelp]

Thanks mark, what am i supposed to do with this were does it go? sorry if it obvious just could see it
Thanks
Tony

 

[MARK858]

Try replacing

fileName = ws.Range("F17").Value

    Set saveAsDialog = Application.FileDialog(msoFileDialogSaveAs)
 
    saveAsDialog.Title = "Please choose location to save this document"
   
        If InStrRev(fileName, ".xlsm") = 0 Then
        fileName = fileName & ".xlsm"
        End If
   
    saveAsDialog.InitialFileName = fileName

with

saveAsDialog = Application.GetSaveAsFilename( _
    FileFilter:="Macro-Enabled Workbook (*.xlsm), *xlsm", InitialFileName:="Tony Test1", Title:="Please choose location to save this document")

change

Dim saveAsDialog As FileDialog

to

Dim saveAsDialog

 

[MARK858]

Just to clarify (adapt the rest of your code to your needs, including removing the Exit Sub line)....

    Dim saveAsDialog

    saveAsDialog = Application.GetSaveAsFilename( _
                   FileFilter:="Macro-Enabled Workbook (*.xlsm), *xlsm", InitialFileName:="Tony Test1", Title:="Please choose location to save this document")
      
    If saveAsDialog <> False Then
        ActiveWorkbook.SaveAs fileName:=saveAsDialog, FileFormat:=52
        Exit Sub
    End If