Runtime error 13 Type Mismatch on an Inputbox value

[Pookiemeister]

EmailTo:
    
    If EmailTo = "" Then
        MsgBox "Uh Oh! " & fName & "," & vbNewLine & "It appears your email correspondents are empty. Let's take care of that now.", vbCritical, "No emails listed to send report to"
        EmailEntryNum = InputBox(fName & "," & vbNewLine & "How many people will you need to send this attachment to? Enter that number below.")
        If IsNumeric(EmailEntryNum) And EmailEntryNum > 0 Then
            MsgBox "YES!" 'For Test Purposes Only
        Else
            MsgBox "AWE! You either did not enter a number or your number was less than 1. Let's try this process this again."
            GoTo EmailTo
        End If
    Else
        'vbYes=6 vbNo=7
        WkAnswer = MsgBox(Greetings & fName & vbNewLine & vbNewLine & "Is this for the current week?" & vbNewLine & vbNewLine & "Select: " & vbNewLine & "Yes = Current Week" & vbNewLine & "No = Previous Week", vbDefaultButton1 + vbYesNo)

I declared "EmailEntryNum" as an integer. So, what I am wanting is if the user enters ANYTHING besides a number, it will jump to the else statement. It sounds simple but I can't get it to work. Here is where the error occurs.

 EmailEntryNum = InputBox(fName & "," & vbNewLine & "How many people will you need to send this attachment to? Enter that number below.")

So this code will run but as stated previously, if I enter anything besides a number, I get a runtime error 13 type mismatch. Thank you.

 

[Joe4]

I declared "EmailEntryNum" as an integer.

By doing this, if they enter anything other than in Integer, it will result in an immediate error and never make it to your IF checks!

You have a few different options:
1. Declare it as "Variant" instead, which will accept anything, then you can do your checks,
- or -
2. Add Error Handling Code to capture and handle what happens when they make an entry that is not an Integer.

 

[Pookiemeister]

Thank you for the suggestions. I usually don't like setting variables to variant but in this case that did the trick. Thank you.

 

[Joe4]

You are welcome!

I agree, I usually don't like it either. However, with input values where you never know what is coming in, if you set it to something other than "Variant", then you need to handle the error situation which arises if they enter in something not valid.

One way or the other, you need to deal with handling bad entries.

 

[Pookiemeister]

Could I not "force" the user to use the correct type? I haven't tried this yet but replace the line of code that shows

If IsNumeric(EmailEntryNum) And EmailEntryNum

with

If err.number = 13 then 
msgbox "Please only enter numbers"

Thank you again

 

[Pookiemeister]

Forgot to add "and put it in a loop" and hopefully that will "train" the user on what values to put in.

 

[Joe4]

Typically, you would set up error handling code like this:

On Error GoTo err_handler
' The section of the code that returns goes here
On Error GoTo 0

'The rest of your code


'Put this just before the end of your code:
Exit Sub

err_handler:
    If err.Number = 13 Then
        MsgBox "Please only enter numbers!", vbOkOnly, "ERROR: TRY AGAIN!"
    Else
        MsgBox err.Number & ":" & err.Description
    End If

End Sub

 

[MARK858]

Could I not "force" the user to use the correct type? I haven't tried this yet but replace the line of code that shows

As an alternative you could try something like the below (untested)

Sub Integer_Only()
    Dim myNum As Integer, myInput As String
    
Restart:
    myInput = InputBox("Enter an integer:")
    
    If myInput = "" Then
        MsgBox "Good Bye", 64, "Action Cancelled"
        Exit Sub
    ElseIf IsNumeric(myInput) Then
        If CDbl(myInput) > Int(myInput) Then
            MsgBox "You entered a Decimal" & vbCrLf & "Try Again", 64, "Integers Only"
            GoTo Restart
        Else
           myNum = myInput
        End If
    Else
        MsgBox "Integers Only" & vbCrLf & "Try Again", 64, "Integers Only"
        GoTo Restart
    End If

End Sub