Running a Macro up Pressing the Numeric Enter Key

[DMumme]

Th following code performs flawlessly. The code is in a sheet module as I do not wish for it to run throughout the entire workbook. The code calls for cell selection anytime a change is made to certain cells. I would like for the cell selections to be made upon pressing the numeric enter key instead as sometimes the cells will not require changing. Ideas?

Private Sub Worksheet_Change(ByVal Target As Range)
    
    On Error GoTo Whoa


    Application.EnableEvents = False


    If Not Target.Cells.CountLarge > 1 Then
        If Not Intersect(Target, Columns(6)) Is Nothing Then ' Column F to G
            Target.Offset(, 1).Select
        ElseIf Not Intersect(Target, Columns(7)) Is Nothing Then ' Column G to O
            Target.Offset(, 8).Select
        ElseIf Not Intersect(Target, Columns(15)) Is Nothing Then ' Column O to U
            Target.Offset(, 6).Select
        ElseIf Not Intersect(Target, Columns(21)) Is Nothing Then ' Column U to A Down 1
            Target.Offset(1, -20).Select
        End If
    End If


Letscontinue:


    Application.EnableEvents = True
    Exit Sub


Whoa:


    MsgBox Err.Description
    Resume Letscontinue
    
End Sub
[end code]

 

[Logit]

.
Paste this code in the sheet module :

Option Explicit


Private Sub Worksheet_Activate()
    Application.OnKey "{ENTER}", "RunIt"
End Sub


Private Sub Worksheet_Deactivate()
    Application.OnKey "{ENTER}", ""
End Sub

In a regular module paste this macro :

Option Explicit


Sub RunIt()
    MsgBox "Hi"
End Sub

You can change the name of the sub to whatever you want so long as the same name is shown in the macro in the sheet module.
Replace the MsgBox command with your macro code.

 

[DMumme]

Thank you for your quick response. Your answer was clear and easy to understand and follow. I really appreciate that.

I created a new Workbook with two sheets: Sheet1 and Sheet2. I copied and pasted your first code into the Sheet2 Module. I copied and pasted your second code into Module1. I went to Sheet2 and selected random cells and hit the numeric enter key and received the MsgBox every time. I then went to Sheet1 and the numeric enter key did not behave as normal. Depressing that key should have selected the row below but it remained on the selected cell.

SIDEBAR - If "{ENTER}" refers to the numeric enter key, how does one refer to the main enter key?

 

[DMumme]

Got it. Just needed to delete the "" at the end of your second code. Found it while researching the SIDEBAR question, the answer of which turns out to be "{~}".
Could not have done it without your help. Thanks again!

 

[Logit]

.
The primary ENTER key is the tilde sympbol ~

Option Explicit


Private Sub Worksheet_Activate()
    Application.OnKey "~", "RunIt"
End Sub


Private Sub Worksheet_Deactivate()
    Application.OnKey "~", ""
End Sub

To turn the numeric ENTER key back to normal try this code:

Private Sub Worksheet_Deactivate()
    Application.OnKey "{ENTER}"
End Sub

If that doesn't work, you may need to create another OnKey macro for that specific sheet and assign the OnKey event to the other macro.

 

[Logit]

You are welcome.