Run Macro for next row

[keyra]

Hello everybody!
I have this macro which concatenates cell L2 and M2 and paste the result in W2. then stops.
My question is how to make this macro to run for the entire columns(L:L & M:M = W:W)? I want to mention that my columns may contain blanks and the sheet is monthly updated (from scracth) and i'm seeking the macro to adapt to the nr of rows. Can you please help me? Thank you!

Dim String1 As String
Dim String2 As String
Dim full_string As String
String1 = Cells(2, 12).Value
String2 = Cells(2, 13).Value
Cells(2, 23).Value = String1 + String2

 

[DanteAmor]

Try this:

Sub macro3()
  With Range("W2:W" & Range("L:M").Find("*", , xlValues, xlPart, xlByRows, xlPrevious).Row)
    .Formula = "=L2&M2"
    .Value = .Value
  End With
End Sub

 

[Micron]

Assuming there's a header row and that column L would always be the one with the most data, then perhaps

Sub Concat()
Dim Lrow As Long, i As Integer

Lrow = Cells(Rows.count, 12).End(xlUp).Row
For i = 2 To Lrow
    Cells(i, 23) = Cells(i, 12) & Cells(i, 13)
Next

End Sub

If M might be the column with the most rows of data then that needs tweaking.

 

[tfurnivall]

It sounds as though you want to calculate the concatenation for all rows where at least column L is non-empty or column M is non empty. Unless you know, by some other mechanism, how many rows you are looking at, the end of your calculations come when both column L and column M in the same row are empty. Right?

sub ConcatWhileDataIsThere (col1 as string, col2 as string, col3 as string,startRow as long)

'    Concat cells in column col1 and col2 into col3
'    Col1 is the first column to look at to find data
'    Col2 is the second column to look at to find data

'    Col3 is the column where you want the concatenated result to be placed

'    StartRow is the row on which you want to start. The routine runs until both Col1 and Col2 are empty on the same row
'    or until you run out of rows - but hopefully that won't happen;-)

dim ThisRow as long
dim str1 as string
dim str2 as string

ThisRow = startRow
str1 = range(Col1 & format(ThisRow)).value
str2 = range(Col2 & format(ThisRow)).value

while not (str1="" and str2="")
      range(Col3 & format(ThisRow)).formula=str1&str2        '    This does the work!
      ThisRow=ThisRow+1
      str1 = range(Col1 & format(Thisrow)).value
      Rtr2 = range(Col2 & format(ThisRow)).value
wend
End Sub

This generalizes your solution, and will start on the StartRow, and examine Col1 and Col2, and if at least one of them is non blank, it will concatenate them and put the result in Col3. It then moves on to the next row. When both Col1 and Col2 are empty, the routine stops.

HTH

Tony

 

[keyra]

Try this:

Sub macro3()
  With Range("W2:W" & Range("L:M").Find("*", , xlValues, xlPart, xlByRows, xlPrevious).Row)
    .Formula = "=L2&M2"
    .Value = .Value
  End With
End Sub

this works just perfect! thank you very much