Run a macro on save sheet

[speedbit]

Note: I'm too basic in VBA/macros...

I have a macro that exports my sheet as CSV without leaving the XLSM file, that works great:

Sub ExportCSV()
    Dim MyFileName As String
    Dim CurrentWB As Workbook, TempWB As Workbook

    Set CurrentWB = ActiveWorkbook
    ActiveWorkbook.ActiveSheet.UsedRange.Copy

    Set TempWB = Application.Workbooks.Add(1)
    With TempWB.Sheets(1).Range("A1")
        .PasteSpecial xlPasteValues
        .PasteSpecial xlPasteFormats
    End With

    MyFileName = CurrentWB.Path & "\" & Left(CurrentWB.Name, InStrRev(CurrentWB.Name, ".") - 1) & ".csv"
    'Optionally, comment previous line and uncomment next one to save as the current sheet name
    'MyFileName = CurrentWB.Path & "\" & CurrentWB.ActiveSheet.Name & ".csv"


    Application.DisplayAlerts = False
    TempWB.SaveAs Filename:=MyFileName, FileFormat:=xlCSVUTF8, CreateBackup:=False, Local:=False
    TempWB.Close SaveChanges:=False
    Application.DisplayAlerts = True
End Sub

I just need to run it automatically each time I save my sheet...
It´s possible?? How to do it?

Thanks in advance! =)

 

[Misca]

Welcome to the board!

Have your VBA Editor open and double click the ThisWorkbook of your file. Make sure you change the "General" to "Workbook" in the left dropdown of your editor. Then select the "Before save" from the left drop down. Now, if you've saved the "ExportCSV" macro saved in your normal module you just call it:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

Call ExportCSV

End Sub

 

[speedbit]

Welcome to the board!

Have your VBA Editor open and double click the ThisWorkbook of your file. Make sure you change the "General" to "Workbook" in the left dropdown of your editor. Then select the "Before save" from the left drop down. Now, if you've saved the "ExportCSV" macro saved in your normal module you just call it:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

Call ExportCSV

End Sub

Just PERFECT!! Solution: accurate. Explanation: BRILLIANT! =D

Thank you very much, for your kindly help and attention.
BR,

 

[speedbit]

Welcome to the board!

Have your VBA Editor open and double click the ThisWorkbook of your file. Make sure you change the "General" to "Workbook" in the left dropdown of your editor. Then select the "Before save" from the left drop down. Now, if you've saved the "ExportCSV" macro saved in your normal module you just call it:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

Call ExportCSV

End Sub

Hi! Here is me again, fightning with this macro! hehehe...

I want to modify it to get just a specific range of columns... let's say "A:F", "H" and "Z:AV"
Could you help me to get the right lines to edit?

Thanksin advance! =)