Rule macro for the current date only

[Hansulet]

I have the following macro:

Sub verificaCNP()


Dim lr As Long
lr = Range("A" & Rows.Count).End(xlUp).Row


For Each c In Range("G3:G" & lr).Cells
If c.Value <> "" Then
c.Activate
ActiveCell.Interior.ColorIndex = xlColorIndexNone
If Len(ActiveCell.Value) <> 13 Then
'MsgBox (ActiveCell.Value & ": CNP incorect - nu are 13 caractere")
ActiveCell.Interior.ColorIndex = 3
ActiveCell.Activate
Exit Sub
Else
If Not VerificCnp(ActiveCell.Value) Then
'MsgBox (ActiveCell.Value & ": CNP incorect.")
ActiveCell.Interior.ColorIndex = 3
ActiveCell.Activate
Exit Sub
End If
End If
End If
Next c
End Sub


I want this macro to be modified in order to rule for the current date only (the date is mentioned in column B)

 

[louisH]

Hi,

Current Date is accessible via the Date function in VBA

Sub verificaCNP()

 Dim lr As Long
 lr = Range("A" & Rows.Count).End(xlUp).Row
 For Each c In Range("G3:G" & lr)
 
    If c.Value = "" Or Cells(c.Row, "B").Value <> Date Then GoTo Skip
    
    c.Interior.ColorIndex = xlColorIndexNone
    
    If Len(c.Value) <> 13 Then
        'MsgBox (ActiveCell.Value & ": CNP incorect - nu are 13 caractere")
        c.Interior.ColorIndex = 3
        c.Activate
        Exit Sub
    Else
        If Not VerificCnp(c.Value) Then
            'MsgBox (ActiveCell.Value & ": CNP incorect.")
            c.Interior.ColorIndex = 3
            c.Activate
            Exit Sub
        End If
    End If
 
Skip:
 
 Next c
 
End Sub

I also changed a few things to make the code clearer, for example removed ActiveCell.Activate which does Nothing. (Activating the activated cell ??)

 

[Hansulet]

Thank you very much. It is working perfect.