REVERSE

[smozgur]

REVERSE function returns the contents of the given text with all the characters reversed.

=LAMBDA(reference,
  TEXTJOIN("",TRUE,MID(reference,SEQUENCE(LEN(reference),,LEN(reference),-1),1)))

Much better version provided by @Peter_SSs:

=LAMBDA(reference,
LET(L,LEN(reference),CONCAT(MID(reference,SEQUENCE(L,,L,-1),1))))

Book1
	A	B
1	123456789	987654321
Sheet1

Cell Formulas
Range	Formula
B1	B1	=REVERSE(A1)

 

[Peter_SSs]

Hi Suat

Suggestion: Since you are using all the characters in the original value, instead of TEXTJOIN using a null string & specifying to skip empty values (of which there will be none) use CONCAT instead?

=LAMBDA(reference,
  CONCAT(MID(reference,SEQUENCE(LEN(reference),,LEN(reference),-1),1)))

.. or perhaps even combine with the LET function:

=LAMBDA(reference,
  LET(L,LEN(reference),CONCAT(MID(reference,SEQUENCE(L,,L,-1),1))))

 

[smozgur]

Suggestion: Since you are using all the characters in the original value, instead of TEXTJOIN using a null string & specifying to skip empty values (of which there will be none) use CONCAT instead?

Beautiful! So I added CONCAT version too.

Funny story of this entry: I was trying to test the Lambda function as I finally have it in Excel, and I don’t know why, this was the first function I could think of as I created the UDF version by using StrReverse VBA function before or likely it was the easiest one that I could understand in the formula form. You know, I am not a real formula person

Then I just realized that @BobUmlas also posted the exact same formula on LinkedIn hours before than I did, and I didn’t see his post until now!

Reversing text in Excel

Here's a formula which will reverse text in cell A1: =TEXTJOIN("",,MID(A1,SEQUENCE(LEN(A1),1,LEN(A1),-1),1)) Or, you can create a named LAMBDA function, txt, to be =LAMBDA(txt,TEXTJOIN("",,MID(txt,SEQUENCE(LEN(txt),1,LEN(txt),-1),1))) and then use =txt(A1) to reverse the text.

www.linkedin.com

Ok, ok. I will stick with coding and leave the formula art to the real experts!