Return header of maximum value column

[flammabubble]

Hey guys,

So I'm using google sheets and I want to search columns E:I for whichever column has the maximum value, and then return cell 1 of that column (i.e. the header).

For example, I want the Primary column to return "Monday" as that has the maximum. If there are two which are equal I'd like it to return either both days or "Multiple"

Primary	Monday	Tuesday	Wednesday	Thursday	Friday
Monday	43	4	2	3	1

I tried getting this to work using IF statements but it was becoming unnecessarily complicated and I'm sure there's an easier way of doing it so any recommendations would be welcome.

Thanks!

 

[mrshl9898]

Index and Match are good to add to your toolbox ☺

=INDEX(E$1:I$1,1,MATCH(MAX(E2:I2),E2:I2,0))

 

[Toadstool]

Hi Flammabubble,

There's another forum for Google Sheets questions but here's my Excel solution.

Flammabubble#.xlsx
	A	B	C	D	E	F	G	H
1	Primary	Monday	Tuesday	Wednesday	Thursday	Friday		Result
2	Monday	43	4	2	3	1		Monday
Sheet1

Cell Formulas
Range	Formula
H2	H2	=IF(COUNTIF(B2:F2,MAX(B2:F2))>1,"Multiple",INDEX(B1:F1,MATCH(MAX(B2:F2),B2:F2,0)))

 

[flammabubble]

Index and Match are good to add to your toolbox ☺

=INDEX(E$1:I$1,1,MATCH(MAX(E2:I2),E2:I2,0))

This is perfect, thank you!

 

[flammabubble]

Hi Flammabubble,

There's another forum for Google Sheets questions but here's my Excel solution.

Flammabubble#.xlsx
	A	B	C	D	E	F	G	H
1	Primary	Monday	Tuesday	Wednesday	Thursday	Friday		Result
2	Monday	43	4	2	3	1		Monday
Sheet1

Cell Formulas
Range	Formula
H2	H2	=IF(COUNTIF(B2:F2,MAX(B2:F2))>1,"Multiple",INDEX(B1:F1,MATCH(MAX(B2:F2),B2:F2,0)))

I could be wrong but I'm pretty sure this is the section for Google Sheets? In any case thanks for your solution!

 

[Fluff]

Another option that should work in sheets

+Fluff 1.xlsm
	A	B	C	D	E	F
1	Primary	Monday	Tuesday	Wednesday	Thursday	Friday
2	Monday, Thursday	43	4	2	43	1
3
Lists

Cell Formulas
Range	Formula
A2	A2	=TEXTJOIN(", ",,FILTER($B$1:$F$1,B2:F2=MAX(B2:F2)))