replace this {";",":","!"} with a table in Power Query

[Matt Allington]

Can anyone tell me how can a I replace a list of values such as {";",":","!"} that exists inside a function such as this

Text.Remove([Contents],{";",":","!"})

with a table of values (single column table). eg

ColumnHeader
;
,
:
!

I have tried creating the table above and then using it in the formula with Table.ToList() but that didn't work. I assume {";",":","!"} is just a list, but I could be wrong.

Thanks for any help.

 

[MarcelBeug]

If the answer is not in the code below, then I didn't understand your question. Or in fact I didn't, but maybe the answer you are looking for is still in the code below.

let
    Source = {";",":","!"},
    Tabled = Table.FromList(Source),
    Custom1 = Table.ToList(Tabled),
    TextCleaned = Text.Remove("M;a;r:celBeug!!!!", Custom1)
in
    TextCleaned

 

[Matt Allington]

Thanks Marcel for your reply. I'm trying to do the opposite. I know I can write the source line as you have. I stead I want to load the list of values in a table (say Excel) and then use that as the source. Is this possible?

 

[citizenbh]

List From Table in Excel:

let
    Source = Excel.CurrentWorkbook(){[Name="Table2"]}[Content],
    ChangedType = Table.TransformColumnTypes(Source,{{"ColumnHeader", type text}}),
    List1= Table.ToList(ChangedType),
TextCleaned = Text.Remove("M;a;r:celBeug!!!!", List1)
in
    TextCleaned

 

[MarcelBeug]

As it is a 1-column table, and a table column is a list, the code can be shortened to:

let
    Source = Excel.CurrentWorkbook(){[Name="Table2"]}[Content],
    List1 = Source[ColumnHeader],
    TextCleaned = Text.Remove("M;a;r:celBeug!!!!", List1)
in
    TextCleaned

 

[Matt Allington]

Thanks both. I tried to do this with the UI but it didn't work. I will investigate again now with this working code. Thanks for your help.