Replace multiple values to another value

[zack8576]

I need to change a group of values to value A, and another group of values to value B
Below is what I have so far, and the code is not working. what am I doing wrong?

Sub CleanUpOutlier()
    With Range("D1", Cells(Rows.Count, "D").End(3))
        .Replace "F21222CJ-08"",F21222CJ-11""", "F21222CJ"
        .Replace "F12315J-67"", F12314J-67""", "F12315J"
    End With
End Sub

 

[bebo021999]

In this sample, there are only 4 items need to be changed. How about actual file?
Assume "F21222CJ-08" and "F21222CJ-11" need to be replaced with "F21222CJ"
and "F12315J-67" and "F12314J-67" need to be replaced with "F12315J"
try:

Option Explicit
Sub CleanUpOutlier()
Dim lr&, i&, j&, rng, oldData, newData
lr = Cells(Rows.Count, "D").End(xlUp).Row
rng = Range("D1:D" & lr).Value
oldData = Array("F21222CJ-08", "F21222CJ-11", "F12315J-67", "F12314J-67") 'list of data need to be changed
newData = Array("F21222CJ", "F21222CJ", "F12315J", "F12315J") ' list of results, in corresponding order with oldData
For i = 1 To lr
    For j = 0 To UBound(oldData)
        If rng(i, 1) Like oldData(j) Then rng(i, 1) = newData(j)
    Next
Next
Range("D1:D" & lr).Value = rng
End Sub

In case there are lots of items need to be changed, try to create a lookup table.