Rename Sheets based on cell values from the first sheet in the workbook.

[iscon]

Hi,

I'm very new to VBA. I have a problem figuring out how to do a macro. I want to rename sheets in my workbook based on values from specific cells on the first page (the front page). Is there someone who can maybe give me some advice.

For example I want to put in values in G3, G4, G5, that will automatically rename sheet 2,3,4 etc. Is this even possible?

Thanks,

V

 

[tyija1995]

Hey, something like this would work for your example given:

Sub ChangeSheetNames()
'Note 31 chars is the max
    Sheets(2).Name = Left(Sheets(1).Range("G3").Value, 31)
    Sheets(3).Name = Left(Sheets(1).Range("G4").Value, 31)
    Sheets(4).Name = Left(Sheets(1).Range("G5").Value, 31)
End Sub

Tabs have a maximum of 31 characters so hence the Left function to take the first 31 characters.

 

[Joe4]

Welcome to the Board!

Here is some code that uses a loop, so it will work on any size range without having to add more rows to your code. I added lots of comments to explain what each step is doing. You may want to add some error handling to check for invalid names or sheet numbers.

Sub MyRenameSheets()

    Dim rng As Range
    Dim cell As Range
    Dim shtnum As Long
        
'   Set range that has names to rename sheets
    Set rng = Sheets("Sheet1").Range("G3:G5")
    
'   Set index of first sheet to rename
    shtnum = 2
    
'   Loop through range
    For Each cell In rng
'       Rename sheet
        Sheets(shtnum).Name = cell.Value
'       Increment sheet index
        shtnum = shtnum + 1
    Next cell
    
End Sub

 

[Joe4]

Here is a variation with some simple error handling that just lets you know what sheet/name it errored out on.

Sub MyRenameSheets()

    Dim rng As Range
    Dim cell As Range
    Dim shtnum As Long
        
'   Set range that has names to rename sheets
    Set rng = Sheets("Sheet1").Range("G3:G6")
    
'   Set index of first sheet to rename
    shtnum = 2
    
    On Error GoTo err_chk
'   Loop through range
    For Each cell In rng
'       Rename sheet
        Sheets(shtnum).Name = cell.Value
'       Increment sheet index
        shtnum = shtnum + 1
    Next cell
    On Error GoTo 0
    
    Exit Sub
    
err_chk:
    MsgBox "Error trying to assign name " & cell.Value & " to sheet " & shtnum
    
End Sub