rename multiple worksheets based on a list

[abcx1975]

I have a workbook with multiple tabs/worksheets. I need to rename the tabs based on a list in one of the tab. The list has 2 columns - A and B. There are names of tabs in column B but they needs to be renamed by their corresponding cells in column A. e.g.
column A Column B
abcd rtyu
htyu gui
usa rss
So the macro should search the tab names and if any of the tab is named as in column B (say rss) then it should be renamed to its corresponding entry in column A (i.e. usa in this case). Any guidance will be much appreciated.+


EDIT: The tab name with the list is fixed - "Summary"

 

[Joe4]

Welcome to the Board!

Try this:

Sub MyRenameSheets()

    Dim lrow As Long
    Dim r As Long
    Dim prevNm As String
    Dim newNm As String
    
    Application.ScreenUpdating = False
    
'   Find last row in column A on Summary sheet with data
    lrow = Sheets("Summary").Cells(Rows.Count, "A").End(xlUp).Row
    
    On Error Resume Next
'   Loop through all rows on Summary sheet starting on row 2
    For r = 2 To lrow
'       Capture values
        prevNm = Sheets("Summary").Cells(r, "A")
        newNm = Sheets("Summary").Cells(r, "B")
'       Rename sheets
        Sheets(prevNm).Name = newNm
    Next r
    On Error GoTo 0
    
    Application.ScreenUpdating = True
        
End Sub

 

[abcx1975]

Thanks a lot. It works perfectly fine and is exactly what was required.

 

[Joe4]

You are welcome!

 

[happyhungarian]

Is it possible to have the macro reference a table instead? So for example, if on the "Summary" tab there's a table with multiple columns and column "A" in the example above is in the 1st column of the table and column "B" in the example above is in the 4th column of the table?