Remove Duplicates in a cell Append formula

[Danny54]

Is there a quick way to remove duplicates in a append formula?

When I insert the formula in column E I get duplicates.
=A1 & ", " & B1 & ", " & C1

I would like for column E to show Blue,Red for row 1 and Blue,Red,Green for row 2 thus removing the duplicates

Thanks

 

[Fluff]

How about

=TEXTJOIN(", ",,UNIQUE(A1:C1,1))

 

[awoohaw]

Try:

Mr Excel Questions 72.xlsm
	A	B	C	D
1
2	Blue	Blue	Red	Blue,Red
3	Blue	Red	Green	Blue,Red,Green
4
Danny54

Cell Formulas
Range	Formula
D2:D3	D2	=TEXTJOIN(",",,UNIQUE(A2:C2,TRUE,FALSE))

 

[Danny54]

Thank you both.

 

[Fluff]

Glad we could help & thanks for the feedback.

 

[Danny54]

May I ask how I might handle removing dupes if the cell data looked like this?

So column D row 1 would show Blue, Red

It looks like they thow multiple data fields in some of the cells seperated by a comma

 

[Fluff]

How about

=TEXTJOIN(", ",,UNIQUE(REDUCE(A1,B1:C1,LAMBDA(x,y,HSTACK(TEXTSPLIT(x,", "),TEXTSPLIT(y,", ")))),1))

 

[Danny54]

I received the same results I'll take your example and work thru it to better understand. I haven't used LAMBDA or HSTACK in the past.
Again Thanks

 

[dreid1011]

I was going to offer this until I saw yours:

=TEXTJOIN(",",,UNIQUE(TEXTSPLIT(A8:C8,","),TRUE))

But here are the results I received:

Book1
	A	B	C	D	E	F	G
8	Blue,Red	Blue	Red	Blue,Red			Blue,Red, Blue, Red
9	Blue	Red	Green	Blue,Red,Green			Blue, Red, Green
Sheet1

Cell Formulas
Range	Formula
D8:D9	D8	=TEXTJOIN(",",,UNIQUE(TEXTSPLIT(A8:C8,","),TRUE))
G8:G9	G8	=TEXTJOIN(", ",,UNIQUE(REDUCE(A8,B8:C8,LAMBDA(x,y,HSTACK(TEXTSPLIT(x,", "),TEXTSPLIT(y,", ")))),1))

 

[Fluff]

I received the same results

In that case can you post some data using the XL2BB add-in.