Reference variable between two modules

[jakobt]

I have two subroutines in the same module named:
Sub JT()
Sub TJ()


in Sub TJ I want to use one of the variables I defined in sub JT()

 

[Fluff]

What is the variable name & what type of variable is it?

 

[jakobt]

Again it is part of a bigger code but I want to use the variable "LR" defined in sub jt() and to be used in sub tj()
sub jt()
dim lr as long
lr= activesheet.cells(Activesheet.rows.count, "B").End(xlup).row
end sub

sub tj()
dim rng as range: set rng = range("v4:v50")
with range("F" & lr + 9).resize(rng.rows.count)
.value =rng.value
.removeduplicates columns:=1, header:=xlno
.sort key1:=range("F" & lr + 9), order1:xlascending, header:=xlno
end with
end sub

 

[Fluff]

If you just want it to get the last row, you're probably better off with a function

Function GetLastRow(Colm As Long, Optional Ws As Worksheet) As Long
   If Ws Is Nothing Then Set Ws = ActiveSheet
   GetLastRow = Ws.Cells(Ws.Rows.Count, Colm).End(xlUp).Row
End Function

Which you can call like

Sub tj()
   Dim rng As Range: Set rng = Range("v4:v50")
   Dim lr As Long
   
   lr = GetLastRow(2)
   With Range("F" & lr + 9).Resize(rng.Rows.Count)
      .Value = rng.Value
      .RemoveDuplicates Columns:=1, Header:=xlNo
      .Sort key1:=Range("F" & lr + 9), order1:=xlAscending, Header:=xlNo
   End With
End Sub

Or you can include the sheet name like

Sub tj()
   Dim rng As Range: Set rng = Range("v4:v50")
   Dim lr As Long
   
   lr = GetLastRow(2, Sheets("sheet2"))
   With Range("F" & lr + 9).Resize(rng.Rows.Count)
      .Value = rng.Value
      .RemoveDuplicates Columns:=1, Header:=xlNo
      .Sort key1:=Range("F" & lr + 9), order1:=xlAscending, Header:=xlNo
   End With
End Sub