Reemplazar en función de una lista

[Miguelsp]

Hola

Para normalizar el contenido de una hoja tengo que pasarme horas "limpiando" los datos de la columna del nombre de la empresa. Usando el reemplazar. Ahora mismo me he hecho una macro con todas las posibilidades a limpiar pero claro según se van añadiendo casos pues tengo que modificar la macro.

Querría saber como remplazar en contenido de una columna si coincide con el contendio que tengo en otra lista

Ejemplo

En una hoja tengo los datos
Columna A
Migule
Mgiuel
Miguel
Mgueli

En otra hoja tengo
Columna A Columna B
Miguel Miguel
Migule Miguel
Mgiuel Miguel
Mgueli Miguel

Quiero hacer una macro que me busque en la columna A de la hoja 1 y me reemplace según lo que ponga en la lista de la otra hoja.

No se si me he explicado...

gracias por anticipado y un saludo

M

 

[galileogali]

A ver con esto:

Sub Reemplaza()

Dim Padron As Range, celPadron As Range
Dim lnglastRowA As Long
lnglastRowA = Hoja2.Cells(Rows.Count, "A").End(xlUp).Row
Set Padron = Hoja2.Range("A1:A" & lnglastRowA)
Application.ScreenUpdating = False
Application.DisplayAlerts = False

For Each celPadron In Padron
If celPadron = Empty Then
Else
    Hoja1.Columns("A:A").Replace What:=celPadron.Value, Replacement:=celPadron.Offset(0, 1).Value, LookAt:=xlPart, _
        SearchOrder:=xlByRows
End If

Next celPadron
Application.DisplayAlerts = True
        
        
End Sub

 

[Miguelsp]

Pues funciona perfectamente... MUCHAS GRACIAS.

Habría posibilidad de utilizar el "nombre" de la hoja en vez del número de hoja?

 

[Greg Truby]

Habría posibilidad de utilizar el "nombre" de la hoja en vez del número de hoja?
~Miguelsp

Usando lo que escribió Gali como base...

Sub Reemplaza()

    Const cstrHojaListado As String = "Mi hoja con el listado"
    Const cstrHojaCorregir As String = "La hoja para corregir"
    'Const cstrHojaListado As String = "Sheet1"
    'Const cstrHojaCorregir As String = "Sheet2"

    Dim rngPadron As Range, celPadron As Range, rngParaCorregir As Range, _
        wsListado As Worksheet, wsCorregir As Worksheet
    
    
    If TypeName(Selection) = "Range" Then
        If Selection.Count > 1 Then
            If Selection.Parent.Name = cstrHojaCorregir Then
                Set rngParaCorregir = Selection
            End If
        End If
    End If
    
    On Error GoTo ErrorHandler
    Set wsListado = Sheets(cstrHojaListado)
    Set wsCorregir = Sheets(cstrHojaCorregir)
    On Error GoTo 0
    
    If rngParaCorregir Is Nothing Then
        Set rngParaCorregir = wsCorregir.Range("A1").CurrentRegion
    End If
    
    If rngParaCorregir.Count = 1 Then
        MsgBox "No se puede localizar el rango para corregir.  Selecciónela y repita.", _
                vbCritical, "Error"
        Exit Sub
    End If
    
    Set rngPadron = wsListado.Range("A1").CurrentRegion.Columns(1)
    
    
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    
    For Each celPadron In rngPadron.Cells
        rngParaCorregir.Replace What:=celPadron.Value, _
                                Replacement:=celPadron.Offset(0, 1).Value, _
                                LookAt:=xlPart, _
                                SearchOrder:=xlByRows
    Next celPadron
    Application.DisplayAlerts = True
            
    Exit Sub
    
ErrorHandler:
'""""""""""""

    Select Case Err.Number
    
        Case 9
        
            MsgBox "No conozco los nombres de la hojas." _
                 & vbCr & vbCr & "¿Alguien los cambió?", vbCritical, "¡Error!"
    
        Case Else
        
            MsgBox "Número de error: " & Err.Number _
                   & vbCr & vbCr & "Descripción: " & Err.Description, vbCritical, "¡Error Desconocido!"
    
    End Select
End Sub

Al leer su pregunta, me hizo pensar en lo que hizo Paul (Hatman) aquí. Entonces jugé con varias ideas pero no me salió nada bien. Sigo pensando de debe de haber una manera de usar el diccionario y/o autocorregir, pero no tengo más tiempo para jugar.
<hr />

¡Hola Gali!

<hr />

Cordialmente,

 

[Greg Truby]

¡Uy! Se me olvidó decirle. La forma más fácil de todo para hacer esto sería usar rangos y/o formulas nombrados. (Y el código arriba todavía no es tan buena como me gustaría tenerlo -- realmente no sería necesario definir la hoja para corregir si el rango para corregir ya existe (quiere decir que el usuario seleccionó celdas antes de correr el macro)) ¡Pero tengo que enfocar en mi trabajo actual! ¡Hasta luego!

 

[Miguelsp]

Muchas gracias Greg