recently input data cannot be searched from frontend

[mrmarc]

So Im using this code in pop up on a front end data base.

Private Sub btnSearch_Click()

Dim rst As Object


Set rst = Me.RecordsetClone
 
rst.FindFirst "[PalletNumber]=" & Me!cboRawInput
 
If rst.NoMatch Then
   MsgBox "Record Not Found"
Else
   Me.Bookmark = rst.Bookmark
End If
 
rst.Close
Set rst = Nothing


Me.Refresh


[Forms]![FloorLogistics]![NavigationSubform].[Form].Refresh


End Sub

It works fine, except when new records are inputted into the table that the code is searching in the backend. I search for the new records and I get the "NoMatch" message: "No Record Found". BUT when I close down this frontend and open it again I can search the new records.

Is there a way I can search the new records without having to close and open my frontend database?

Thanks,

 

[HiTechCoach]

Using Refresh is be part of the problem. You need to use Requrey to get new records.

Refresh: - updates just the records currently in the recordset. No new records are added since the recordset was was originally generated.

Requery - executes the recordset generation again (same effect as closing a form or report and opening it again). This will add any new records added after the recordset was originally generated.

I would try this:

Private Sub btnSearch_Click()

Dim rst As Object

Me.Requery ' <<<< load any new records before searching
  
Set rst = Me.RecordsetClone 
 
rst.FindFirst "[PalletNumber]=" & Me!cboRawInput
 
If rst.NoMatch Then
   MsgBox "Record Not Found"
Else
   Me.Bookmark = rst.Bookmark
End If
 
rst.Close
Set rst = Nothing


[Forms]![FloorLogistics]![NavigationSubform].[Form].Requery   ' Use requery to add new records and remove deleted

End Sub

 

[mrmarc]

Thanks Boyd! Can you help me out with this one?

http://www.mrexcel.com/forum/micros...g-records-linked-table-over-local-server.html