Reading the ShowModal Property of UserForm at run time ?

[Jaafar Tribak]

Is there a way to read the ShowModal Property at runtime ?

Something like this :

Private Sub UserForm_Activate()
    MsgBox Me.ShowModal
End Sub

Which obviously generates a compile error

Regards.

 

[Jaafar Tribak]

I can't seem to find a native way to determine if a userform is Modal or Modeless at run time

I had to resort to the Windows API to find an cheesy workaround. The following custom function IsFormModal seems to work

Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
    Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As LongPtr) As LongPtr
#Else
    Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    Private Declare Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long
#End If

Private Sub UserForm_Activate()
    If IsFormModal(Me) Then
        MsgBox Me.Name & " is modal"
    Else
        MsgBox Me.Name & " is modeless"
    End If
End Sub

Private Function IsFormModal(Frm As Object) As Boolean
    #If VBA7 Then
        Dim hwnd As LongPtr
    #Else
        Dim hwnd As Long
    #End If

    IsFormModal = Not CBool(SetFocus(Application.hwnd))
    hwnd = FindWindow("ThunderDFrame", Frm.Caption)
    If hwnd Then
        Call SetFocus(hwnd)
    End If
End Function