Read information inside html

[S_White]

Hello
I have this URL: Candriam Equities L Australia Class C AUD Cap, LU0078775011:AUD historical prices - FT.com. Using Chrome I can inspect the elements and there I need to be able to read the information about symbol=3280 from data-module-name="HistoricalPricesApp" I've tried various ways, but without any luck.

So far my code is:

Dim XMLHTTP As New MSXML2.XMLHTTP, HtmlDoc As New HTMLDocument, TableObj As Object
With XMLHTTP
    .Open "GET", "https://markets.ft.com/data/funds/tearsheet/historical?s=LU0078775011:AUD", False
    .send
    HtmlDoc.body.innerHTML = .responseText
End With
Set TableObj = HtmlDoc.getElementsByTagName("table")

but I suppose the information about the symbol is outside the table?

Anyone who can assist?

/S_White

 

[Kerryx]

If it is just a case of pulling in the historical prices table use the option in excel under Data , Get DATA select from web , input your webpage address and select the table you need, you can edit it before loading to your webpage

 

[S_White]

Well, as the information might be outside the table, I'm looking for a way where I can get the information.

It's the "symbol":"3280" information I'm trying to scrape.

 

[John_w]

Does this get what you want?

Public Sub Get_Attribute_Value()
    
    #If VBA7 Then
        Dim XMLHTTP As New MSXML2.XMLHTTP60
    #Else
        Dim XMLHTTP As New MSXML2.XMLHTTP
    #End If
    Dim HTMLdoc As New HTMLDocument
    Dim div As HTMLDivElement
    
    With XMLHTTP
        .Open "GET", "https://markets.ft.com/data/funds/tearsheet/historical?s=LU0078775011:AUD", False
        .send
        HTMLdoc.body.innerHTML = .responseText
    End With
    
    Set div = HTMLdoc.querySelector("[data-module-name='HistoricalPricesApp']")
    Debug.Print div.getAttributeNode("data-mod-config").NodeValue
    
End Sub

{"inception":"1997-06-27T00:00:00Z","symbol":"3280"}

 

[S_White]

John,

Thanks a $,$$$,$$$ - sorted!

I must admit that I haven't used the 'querySelector' before, but from debugging the output I can see what a difference it makes.

Cheers

S_White