RANDDATA

[RicoS]

RANDDATA Creates a 2D array (of n rows) of random data from a 2D array of fields/dimension data.

SORTROWS Lambda Function is used in this function.

=LAMBDA(data,noOfRows,incValueColumn,minValue,maxValue,noOfDecimals,
   LET(d,data,nOR,noOfRows,
      c,COLUMNS(d),r,ROWS(d),
      sC,SEQUENCE(,c+incValueColumn),sR,SEQUENCE(r),
      mxRows,INDEX(SORTROWS(TRANSPOSE(ISBLANK(d)*(sR-1)),1),,1),
      lastRow,TRANSPOSE(IF(mxRows=0,r,mxRows)),
      sNR,SEQUENCE(nOR+1,c),rw,INT(sNR/(c+1)),sNR_1,SEQUENCE(nOR+1),
      firstRows,2-(rw=0),
      lastRows,IF(rw=0,1,(rw*0)+lastRow),
      randArr,IF(incValueColumn,ROUND(RANDARRAY(nOR,1,minValue,maxValue,FALSE),noOfDecimals)),
      amountColumn,IF(incValueColumn,IF(sNR_1=1,"Amount",INDEX(randArr,sNR_1-1))),
      dataRow,IF(sC=c+1,amountColumn,INDEX(d,RANDBETWEEN(firstRows,lastRows),sC)),
   dataRow)
)

Book1
	A	B	C	D	E	F	G	H	I	J	K	L
1	Country	Area	Month	Person	Currency		Country	Area	Month	Person	Currency	Amounts
2	Scotland	North	Jan	Andy	GBP		Italy	South	Dec	Barry	USD	1495
3	England	East	Feb	Dave	USD		Wales	West	Mar	Karen	GBP	1139
4	Wales	South	Mar	Michelle			Wales	East	Sep	Andy	GBP	654
5	Ireland	West	Apr	Esme			Wales	West	May	Esme	USD	1203
6	France		May	Barry			Italy	South	Aug	Esme	USD	914
7	Italy		Jun	Karen			Scotland	East	Jun	Barry	USD	1192
8			Jul				Wales	South	Sep	Karen	USD	842
9			Aug				Scotland	West	Jul	Michelle	GBP	811
10			Sep				France	South	Apr	Andy	USD	457
11			Oct				England	West	Aug	Barry	USD	1495
12			Nov				Ireland	West	Aug	Dave	USD	278
13			Dec				Ireland	North	Apr	Andy	USD	625
14							England	North	May	Karen	GBP	1030
15							Italy	West	Sep	Karen	USD	458
16							Scotland	West	Apr	Barry	GBP	715
17							England	South	Feb	Michelle	GBP	945
18							Ireland	West	Jun	Andy	GBP	1216
19							England	North	Jul	Andy	GBP	446
20							England	North	Oct	Andy	GBP	443
21							France	South	Feb	Michelle	GBP	1339
Data

Cell Formulas
Range	Formula
G1:L21	G1	=RANDDATA(A1:E13,20,1,200,1500,0)
Dynamic array formulas.

 

[Xlambda]

The idea to create rand data is super cool !! Kudos for that !! ?✌
Did not understand, what sortrows function (that calls other 3 dif lambdas) does here?
To calculate the "depth" (height) of each column of "data" array?
For that you can use only MMULT(SEQUENCE(,ROWS(data))^0,--(data<>"")) You will get (including headers row) : 7,13,7,3 (let's call it mr)
Then a simple INT(RANDARRAY(nofrows,COLUMNS(data))*mr)+1 will create the array of random row indexes
This is how it looks, a lambda that addresses the core of this concept (adding headers or values column is simple array cosmetics, no problems there, although I think we need more columns with values in a real life alike data set, not only 1, like real dates , unit prices, %discounts, costs, units sold, totals..etc )
ARANDDATA(a,n) a: "data" array ; n: nr. rows to be generated

=LAMBDA(a,n,LET(c,COLUMNS(a),INDEX(a,INT(RANDARRAY(n,c)*MMULT(SEQUENCE(,ROWS(a))^0,--(a<>"")))+1,SEQUENCE(,c))))

Book1
	A	B	C	D	E	F	G	H	I	J	K	L
1							=ARANDDATA(A2:E13,20)
2	Scotland	North	Jan	Andy	GBP		England	East	Jun	Andy	GBP
3	England	East	Feb	Dave	USD		England	North	Apr	Andy	GBP
4	Wales	South	Mar	Michelle			England	North	Jul	Dave	GBP
5	Ireland	West	Apr	Esme			England	North	Jan	Andy	USD
6	France		May	Barry			France	East	May	Andy	USD
7	Italy		Jun	Karen			Ireland	North	Jan	Dave	USD
8			Jul				Ireland	North	Jan	Dave	GBP
9			Aug				France	North	Jan	Dave	GBP
10			Sep				France	South	Aug	Andy	USD
11			Oct				Wales	West	Sep	Karen	USD
12			Nov				France	East	May	Esme	USD
13			Dec				Italy	South	Aug	Barry	USD
14							Wales	West	Aug	Michelle	USD
15							England	North	Sep	Barry	GBP
16							Scotland	North	May	Michelle	GBP
17							Wales	North	Jan	Dave	GBP
18							Italy	South	Feb	Barry	USD
19							Wales	West	Sep	Andy	USD
20							England	North	Sep	Karen	GBP
21							Italy	East	Oct	Esme	GBP
22
Sheet3

Cell Formulas
Range	Formula
G1	G1	=FORMULATEXT(G2)
G2:K21	G2	=ARANDDATA(A2:E13,20)
Dynamic array formulas.