Put text in a different cell than the function is.

[BAKELOVEMORE]

I want to move the IF statements into column BI so the function is not shown in the function bar. As it is now, have to delete the function to place other text.
I have tried using concat, text, isnumber, &, vlookup, xlookup, textjoin, etc. both in cells and in VBA and I just cannot get it to work.
Check G column for "ØCAM" and IF TRUE insert "LRV NOT CONNECTING TO NETWORK" in H column same row but have the if check in BI or VBA so it doesn't show in column H so other data can be typed in without having to delete the statement.

Thanks

 

[StephenCrump]

Welcome to the Forum!

This sounds like a job for VBA. Perhaps something along these lines:

'In the relevant Sheet module
Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rngToMonitor As Range, r As Range
    Dim s As String
    
    Set rngToMonitor = Intersect(Range("G3:G100"), Target)
    
    If Not rngToMonitor Is Nothing Then
        s = "LRV NOT CONNECTING TO NETWORK"
        Application.EnableEvents = False
        For Each r In rngToMonitor
            If r.Value = "ØCAM" Then
                r.Offset(, 1).Value = s
            Else
                If r.Offset(, 1).Value = s Then r.Offset(, 1).Value = ""
            End If
        Next r
        Application.EnableEvents = True
    End If

End Sub

 

[BAKELOVEMORE]

Welcome to the Forum!

This sounds like a job for VBA. Perhaps something along these lines:

'In the relevant Sheet module
Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rngToMonitor As Range, r As Range
    Dim s As String
   
    Set rngToMonitor = Intersect(Range("G3:G100"), Target)
   
    If Not rngToMonitor Is Nothing Then
        s = "LRV NOT CONNECTING TO NETWORK"
        Application.EnableEvents = False
        For Each r In rngToMonitor
            If r.Value = "ØCAM" Then
                r.Offset(, 1).Value = s
            Else
                If r.Offset(, 1).Value = s Then r.Offset(, 1).Value = ""
            End If
        Next r
        Application.EnableEvents = True
    End If

End Sub

That worked perfectly. I need to get further in my vba manual I see. A lot more elegant than the brute force coding I was trying.