Protect Multiple Sheet at once

[glynn1969]

Hello

Is it possible to apply a vba protect multiple sheets at once? (I have the VBA already - kindly supplied on this site)

Thank you

 

[mumps]

To protect all sheets in a workbook:

Sub ProtectSheets()
    Application.ScreenUpdating = False
    Dim ws As Worksheet
    For Each ws In Sheets
        ws.Protect
    Next ws
    Application.ScreenUpdating = True
End Sub

 

[glynn1969]

Thank you

I am trying to combine with the macro below which ask the user to select which cells to protect.

My workbook has 5 sheets - sheet1,sheet2, etc and i want to protect the same cells on sheet2, sheet3, etc but not sheet1.



Sub ProtectRange()
Dim Rng As Range
ActiveSheet.Unprotect
Set Rng = Application.InputBox("Type or select the range to protect:", Type:=8)
Cells.Locked = False
Rng.Locked = True
ActiveSheet.Protect
End Sub

 

[shg]

Sub ProtectRange()
  Dim r             As Range
  Dim sAdr          As String
  Dim i             As Long
  Dim wks           As Worksheet

  Set r = Application.InputBox("Type or select the range to protect:", Type:=8)
  sAdr = r.Address

  For i = 2 To Worksheets.Count
    Set wks = Worksheets(i)
    With wks
      .Unprotect
      .Cells.Locked = False
      .Range(sAdr).Locked = True
      .Protect
    End With
  Next i
End Sub