Printing Dictionary Values

[Ronanm]

Hi

I can print Dictionary values to the immediate window by running the code below, but I wanted to know how I print "all" the Dictionary values into an Excel sheet?

Public Sub DictionaryExamples()

    Dim exampleValues As Variant
    Dim i As Long
    Dim aKey As String
    Dim aValue As Integer
    Dim bValue As String
    Dim exampleDict As Object

    'Load values into a variant array
    exampleValues = Range("A1:C12").Value

    'Instantiate a dictionary
    Set exampleDict = CreateObject("scripting.dictionary")

    'Read all keys and values, and add them to the dictionary
    For i = 1 To UBound(exampleValues)
        aKey = CStr(exampleValues(i, 1))
        aValue = CInt(exampleValues(i, 2))
        bValue = CStr(exampleValues(i, 3))
        exampleDict.Add aKey, Array(aValue, bValue)
             Debug.Print aKey, aValue, bValue
    Next i
End Sub

Thanks

 

[Fluff]

How about

Public Sub DictionaryExamples()

    Dim exampleValues As Variant
    Dim i As Long
    Dim aKey As String
    Dim aValue As Integer
    Dim bValue As String
    Dim exampleDict As Object

    'Load values into a variant array
    exampleValues = Range("A1:C12").Value

    'Instantiate a dictionary
    Set exampleDict = CreateObject("scripting.dictionary")

    'Read all keys and values, and add them to the dictionary
    For i = 1 To UBound(exampleValues)
        aKey = CStr(exampleValues(i, 1))
        aValue = CInt(exampleValues(i, 2))
        bValue = CStr(exampleValues(i, 3))
        exampleDict.Add aKey, Array(aValue, bValue)
    Next i
      Range("E1").Resize(exampleDict.Count).Value = Application.Transpose(exampleDict.Keys)
      Range("F1").Resize(exampleDict.Count, 2).Value = Application.Index(exampleDict.Items, 0, 0)
End Sub

 

[Ronanm]

Thanks Fluff

That will do nicely. Appreciate it.

 

[Fluff]

You're welcome & thanks for the feedback