Print XLS files in folder based on name

[scotsrule08]

Good day Friends!

I have a folder with dozens of spreadsheets that I need to print. I only want to print the files that contain the word "COMPLETE" in the filename.

It would be much preferred to not have to open each file to print as there are a ton.

Thank you!

 

[DanteAmor]

Use This.
Cange "C:\trabajo" by the name of your folder.

Option Explicit
'
Declare Function apiShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
    ByVal hwnd As Long, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) _
    As Long
'
Public Sub PrintFile(ByVal strPathAndFilename As String)
 
    Call apiShellExecute(Application.hwnd, "print", strPathAndFilename, vbNullString, vbNullString, 0)
 
End Sub
'
Sub Print_File_Complete()
    Dim ruta As String
    Dim arch
    ruta = "C:\trabajo\"
    arch = Dir(ruta & "*.xlsx")
    Do While arch <> ""
        If InStr(1, UCase(arch), "COMPLETE") > 0 Then
            PrintFile (ruta & arch)
        End If
        arch = Dir()
    Loop
End Sub