positioning a shape on a calendar based on a given date.

[ifu06416]

Hello,

I'm trying to build a customized Gantt chart on excel.

I have a template with task start dates (col B) and end dates (col C) followed by the 12 months of the year (cols E-P).

I have the code below to generate the task duration bars.

The difficulty Im having is figuring out how to position the start of the bar relative to the task start month (col B) and the end of the bar relative to the end month (col C).

If anyone has any ideas it would be appreciated.

Regards,

John.

Sub CreateShapes2()

Dim Start_Diamond As Shape
Dim End_Diamond As Shape
Dim conn As Shape
Dim rngPlace As Excel.Range

'set reference to a worksheet
Set w = ActiveSheet

'add Start Diamond
 Set rngPlace = w.Range("E4")
 With rngPlace
 Set Start_Diamond = w.Shapes.AddShape(msoShapeDiamond, 300.5, 35, 8.5, 9.6)


'Add end diamond
Set End_Diamond = w.Shapes.AddShape(4, 600.5, 35, 8.5, 9.6)

'Set the connector link
Set conn = w.Shapes.AddConnector(msoConnectorStraight, 15, 150, 15, 150)

conn.ConnectorFormat.BeginConnect Start_Diamond, 1
conn.ConnectorFormat.EndConnect End_Diamond, 1
conn.RerouteConnections


End With
End Sub

 

[Domenic]

I have amended your macro as follows . . .

Sub CreateShapes2()

    Dim ws As Worksheet
    Dim Start_Diamond As Shape
    Dim End_Diamond As Shape
    Dim conn As Shape
    Dim Start_Range As Range
    Dim End_Range As Range
    Dim Start_Pos As Single
    Dim End_Pos As Single
    
    On Error GoTo errorHandler
    
    'set reference to a worksheet
    Set ws = ActiveSheet
    
    'find start and end ranges
    With Application
        Set Start_Range = .Index(ws.Range("E4:P4"), .Match(Format(ws.Range("B4").Value, "mmm"), ws.Range("E3:P3"), 0))
        Set End_Range = .Index(ws.Range("E4:P4"), .Match(Format(ws.Range("C4").Value, "mmm"), ws.Range("E3:P3"), 0))
    End With
    
    'find start position
    With Start_Range
        Start_Pos = .Left + (.Width / 2) - (8.5 / 2)
    End With
    
    'find end position
    With End_Range
        End_Pos = .Left + (.Width / 2) - (8.5 / 2)
    End With
    
    'add Start Diamond
     Set Start_Diamond = ws.Shapes.AddShape(msoShapeDiamond, Start_Pos, Start_Range.Top + 2, 8.5, 9.6)
    
     'add End Diamond
     Set End_Diamond = ws.Shapes.AddShape(msoShapeDiamond, End_Pos, End_Range.Top + 2, 8.5, 9.6)
    
    'Set the connector link
    Set conn = ws.Shapes.AddConnector(msoConnectorStraight, 15, 150, 15, 150)
    
    conn.ConnectorFormat.BeginConnect Start_Diamond, 1
    conn.ConnectorFormat.EndConnect End_Diamond, 1
    conn.RerouteConnections
    
exitHandler:
    Exit Sub
    
errorHandler:
    MsgBox "Error " & Err.Number & ":  " & Err.Description, vbCritical, "Error"
    Resume exitHandler
    
End Sub

Note that I have also added an error handler.

Hope this helps!

 

[ifu06416]

I have amended your macro as follows . . .

Sub CreateShapes2()

    Dim ws As Worksheet
    Dim Start_Diamond As Shape
    Dim End_Diamond As Shape
    Dim conn As Shape
    Dim Start_Range As Range
    Dim End_Range As Range
    Dim Start_Pos As Single
    Dim End_Pos As Single
   
    On Error GoTo errorHandler
   
    'set reference to a worksheet
    Set ws = ActiveSheet
   
    'find start and end ranges
    With Application
        Set Start_Range = .Index(ws.Range("E4:P4"), .Match(Format(ws.Range("B4").Value, "mmm"), ws.Range("E3:P3"), 0))
        Set End_Range = .Index(ws.Range("E4:P4"), .Match(Format(ws.Range("C4").Value, "mmm"), ws.Range("E3:P3"), 0))
    End With
   
    'find start position
    With Start_Range
        Start_Pos = .Left + (.Width / 2) - (8.5 / 2)
    End With
   
    'find end position
    With End_Range
        End_Pos = .Left + (.Width / 2) - (8.5 / 2)
    End With
   
    'add Start Diamond
     Set Start_Diamond = ws.Shapes.AddShape(msoShapeDiamond, Start_Pos, Start_Range.Top + 2, 8.5, 9.6)
   
     'add End Diamond
     Set End_Diamond = ws.Shapes.AddShape(msoShapeDiamond, End_Pos, End_Range.Top + 2, 8.5, 9.6)
   
    'Set the connector link
    Set conn = ws.Shapes.AddConnector(msoConnectorStraight, 15, 150, 15, 150)
   
    conn.ConnectorFormat.BeginConnect Start_Diamond, 1
    conn.ConnectorFormat.EndConnect End_Diamond, 1
    conn.RerouteConnections
   
exitHandler:
    Exit Sub
   
errorHandler:
    MsgBox "Error " & Err.Number & ":  " & Err.Description, vbCritical, "Error"
    Resume exitHandler
   
End Sub

Note that I have also added an error handler.

Hope this helps!

Oh wow, you've actually done it for me ?

That works perfectly, thanks so much.

Regards,

John.

 

[Domenic]

You're very welcome, and thanks for the feedback.

Cheers!