Pivot table - Show Report Filter Pages - shortens tab names to 26 characters

[gnosttam]

Hello,

First time poster. Great website.

I have an issue with a Pivot table. I am using 'Show Report Filter Pages' function. I ensured that the tab names that would be populated have equal to or less than 31 characters (to abide by the 31-character limit). The problem is, when I use the function, it populates my tabs with only 26 characters and will truncate anything past the 26 characters. Has anyone come across this issue? Aside from shortening my tabs to 26 characters, is there a workaround to ensure that the full 31 character limit gets populated?

Thanks.

 

[ParamRay]

Could do similar using a macro?

Public Sub ShowReportFilterPages()
  Dim wksSource As Worksheet
  Dim wksTarget As Worksheet
  Dim pvtTable As PivotTable
  Dim pvtField As PivotField
  Dim pvtItem As PivotItem
  
  On Error GoTo ErrHandler
  Set wksSource = ThisWorkbook.Sheets("SHEET NAME GOES HERE")
  Set pvtTable = wksSource.PivotTables("TABLE NAME GOES HERE")
  Set pvtField = pvtTable.PageFields("FIELD NAME GOES HERE")
  
  For Each pvtItem In pvtField.PivotItems
    Set wksTarget = ThisWorkbook.Sheets.Add
    wksTarget.Name = pvtItem.Value
    pvtField.CurrentPage = pvtItem.Value
    pvtTable.TableRange2.Copy wksTarget.Range("A1")
  Next pvtItem
  
TidyUp:
  Set wksSource = Nothing
  Set wksTarget = Nothing
  Set pvtTable = Nothing
  Set pvtField = Nothing
  Set pvtItem = Nothing
  Exit Sub
  
ErrHandler:
  MsgBox Err.Description, vbCritical, "Error " & Err.Number
  Resume TidyUp
End Sub

 

[ParamRay]

Any luck?