Pegar una lista de valores sólo en celdas visibles

[yomisma2000]

Buenos días!

Quería saber si existía alguna forma de pegar una lista de por ejemplo 5 valores consecutivos de una columna que hay en una hoja en otra hoja que está filtrada y conseguir que pegue esos valores solo en las celdas visibles de esa hoja. A la hora de pegar en la hoja destino selecciono sólo celdas visibles, pero no funciona.. los pega en todas las celdas que hay entre medias también.

Esto solo me funciona si tengo solo un valor que quiero pegar en varias celdas no consecutivas, selecciono celdas visibles y lo hace bien. Pero si es una lista de x valores y selecciono las celdas visibles donde quiero que vayan (el mismo numero de celdas, claro), no funciona.

Gracias

 

[DanteAmor]

Hola @yomisma2000 y bienvenida a MrExcel.

Una opción podría ser con una macro.

Prueba con la siguiente macro. Al ejecutarla, primero debes seleccionar las celdas a copiar, presionar enter, después seleccionar el igual número de celdas donde vas a pegar, presionas enter y la macro pone los valores en las celdas destino.

Si el número de celdas destino no es igual al número de celdas copiadas te envía un mensaje:

Sub copiar_pegar_visibles()
  Dim rng1 As Range, rng2 As Range, c As Range
  Dim n1 As Long, n2 As Long, i As Long
  
  On Error Resume Next
  With Application
    Set rng1 = .InputBox("Selecciona el rango a copiar", Default:=Selection.Address, Type:=8)
    If rng1 Is Nothing Then Exit Sub
    
    Set rng2 = .InputBox("Selecciona el rango para pegar", Default:=Selection.Address, Type:=8)
    If rng2 Is Nothing Then Exit Sub
  End With
  On Error GoTo 0
  
  n1 = rng1.Columns(1).SpecialCells(xlCellTypeVisible).Count
  n2 = rng2.Columns(1).SpecialCells(xlCellTypeVisible).Count
  If n1 = n2 Then
    For Each c In rng2.Columns(1).SpecialCells(xlCellTypeVisible).Cells
      i = i + 1
      c.Value = rng1.Cells(i)
    Next
  Else
    MsgBox "El número de filas a pegar es distinto"
  End If
End Sub

-----
Nota Macro:

Si eres nueva en macros, realiza lo siguiente:​

1. Abre tu archivo de excel​

2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11​

3. En el menú elige Insertar / Módulo​

4. En el panel del lado derecho copia la macro​

5. Para ejecutarla presiona F5​

-----


Avísame el resultado de las pruebas y estaré de regreso tan pronto pueda.
Saludos
Dante Amor