Pasting to Word

[Orion19]

Hello!

I'm attempting to copy a range from Excel and paste into a blank word document. The following code works up to the point where the pasting should occur. If I run the macro a new word documents open but it remains blank. The data is copied and makes it to the clipboard but won't paste unless done manually. Any ideas? I'm running Excel for Mac 2017. Here's the code (I need the filter later but am just using it with dummy data now):

Sub PasteToWord()     
Dim wApp As Word.Application
Dim wDoc As Word.Document


On Error Resume Next
Set wApp = New Word.Application
wApp.Visible = True


Documents.Add DocumentType:=wdNewBlankDocument


wDoc.Content.InsertAfter Range("A1")


     
Range("A1:A4").Select
    Selection.AutoFilter
    ActiveSheet.Range("$A$1:$A$4").AutoFilter Field:=14, Criteria1:=RGB(255 _
        , 0, 0), Operator:=xlFilterCellColor
    Selection.Copy


wDoc.Activate
Selection.Paste


End Sub

 

[Macropod]

Since you're running the code from Excel, Selection.Paste is assumed to be Excel.Selection.Paste. Regardless, you don't need to activate the document or select anything. All you need is:
wdDoc.Paste

 

[Orion19]

Thanks for the reply!!

I gave that a shot but unfortunately had the same result (only a blank word doc opens). I thought maybe I needed to copy the data before the word doc opens and reorganized the code as follows, but the result is still the same. Any other ideas? Thank you again!!!

Sub PasteToWord()     
Dim wApp As Word.Application
Dim wDoc As Word.Document


Range("A1:A4").Select
Selection.Copy


On Error Resume Next
Set wApp = New Word.Application
wApp.Visible = True


Documents.Add DocumentType:=wdNewBlankDocument
wDoc.Paste




End Sub

 

[Macropod]

That'll be because you haven't told Word what wDoc is! Instead of:
Documents.Add DocumentType:=wdNewBlankDocument
you should have:
Set wDoc = Documents.Add(DocumentType:=wdNewBlankDocument)

 

[Orion19]

I gave it a shot but still got the same result. The data is in the clipboard but the word document is still blank. I'm really sorry if I'm making obvious missteps. This is my first attempt at communication across applications so I appreciate the help.

I'm going to keep reading but if you have any other ideas I'm all ears (or eye I guess)! Thanks!

That'll be because you haven't told Word what wDoc is! Instead of:
Documents.Add DocumentType:=wdNewBlankDocument
you should have:
Set wDoc = Documents.Add(DocumentType:=wdNewBlankDocument)

 

[Macropod]

The following should work just fine, but I can't see why you'd want to both insert a cell's content and use copy/paste for an overlapping range.

Sub PasteToWord()
Dim wApp As New Word.Application, wDoc As Word.Document, xlSht As Worksheet
Set xlSht = ActiveSheet
With wApp
  .Visible = True
  Set wDoc = .Documents.Add
  xlSht.Range("$A$1:$A$4").Copy
  With wDoc.Range
    .Paste
    .InsertBefore xlSht.Range("A1")
  End With
End With
Set wDoc = Nothing: Set wApp = Nothing: Set xlSht = Nothing
End Sub