Passing ParamArray to another sub ???

[keldsor]

I want to gather an unkown number of childrens ID's from one sub to another as easy as posible - something like:

Public Sub setUpFamily(IdF As Long, IdM As Long, gift As String, ParamArray id())   <<<<<<<<<< FROM HERE !!!!!!!!!!!!!!!!!!!!!
    danPar IdF, IdM, gift
    lineUpChildrenTo IdF, IdM, id() <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< USING this !!!!!!!!!!!!
End Sub


Public Sub lineUpChildrenTo(IdF As Long, IdM As Long, ParamArray id())   <<<<<<<<<<<<<<<<< TO HERE 
    ' Lines up the children to the right of the parents evenly spaced

(I have some working code here !!!!)

End Sub

The setUpFamily ( .... ) is called something like this:

setUpFamily 26,27,"31-03-1931 i Hasle Sogn", 35,32,33,28,34 <<<<<<<< sometime more Id's for the children - here only 5 !

But I can't get it to work at all !

 

[Domenic]

When the sub setUpFamily passes the array id() to the sub lineUpChildrenTo, the array is passed as the first argument to the array id() in lineUpChildrenTo. So the array id() within lineUpChildrenTo contains a single element consisting of the original array of values. Therefore, id(0) will refer to the original array, and id(0)(0) will refer to the first element of that array, and so on.

id(0)(0) ===> first element
id(0)(1) ===> second element
etc
'
'
'

Hope this helps!

 

[shg]

Sub main()
  setUpFamily 10, 20, "Gold", 1, 2, 3, 4, 5
End Sub

Public Sub setUpFamily(IdF As Long, IdM As Long, gift As String, ParamArray id() As Variant)
  Dim i As Long
  
  Stop  ' and look in the Locals window
  
  Debug.Print "setUpFamily:"
  For i = 0 To UBound(id)
    Debug.Print id(i)
  Next i
  
  lineUpChildrenTo IdF, IdM, id
End Sub


Public Sub lineUpChildrenTo(IdF As Long, IdM As Long, ParamArray id() As Variant)
  Dim i             As Long
  
  Stop  ' and look in the Locals window
  
  Debug.Print "lineUpChildrenTo:"
  For i = 0 To UBound(id(0))  ' << compare vs above
    Debug.Print id(0)(i)      ' << compare vs above
  Next i
End Sub

Put Stop statements in setUpFamily and lineUpChildren as shown and look in the Locals window.

In setUpFamily, id is a 1D array, but in lineUpChildren it is a 2D array, because it was passed as a single argument.

EDIT: Clearly slow on the draw today.

 

[keldsor]

Thx, works nicely !