Passing Object Error

[Jonas Offersen]

So, this code isn't working for me. For whatever reason, I get an " Error 424 - object required" error, when I try to pass the object into the sub.
I do not get this error when I try to use it outside of the function.

Private Sub Form_Load()
    Dim obj As ListBox
    Set obj = Me.ListNiveau
    obj.visible = False [COLOR=#0000ff]'This is working![/COLOR]
    LayoutControls.SetListBoxColWidths (obj) [COLOR=#0000ff]'This returns error 424.[/COLOR]
End Sub

The code bellow is altering the textbox columns as working as intended.

Public Sub SetListBoxColWidths(ListBoxName As ListBox)

    Dim i As Integer
    Dim j As Integer

    Dim ColMaxWidth(2) As Double ' for 3 column listbox
   [COLOR=#0000ff]
'Initialise to zero[/COLOR]
    For j = 0 To 2
        ColMaxWidth(j) = 0
    Next j
   [COLOR=#0000ff]
'itereate thru each item in listbox and find max size[/COLOR]
    For i = 0 To ListBoxName.ListCount - 1
        For j = 0 To 2
            If ColMaxWidth(j) < (Len(ListBoxName.Column(j, i)) * 125) Then
                ColMaxWidth(j) = (Len(ListBoxName.Column(j, i)) * 125)
            End If
        Next j
    Next i
[COLOR=#0000ff]
'display columnwidths based on max size[/COLOR]
    ListBoxName.ColumnWidths = ColMaxWidth(0) & ";" & ColMaxWidth(1) & ";" & ColMaxWidth(2) & ""

End Sub

As it turns out I don't actually need this right now. But I would like to know what I'm doing wrong regardless, for next time.

 

[RoryA]

You need to remove the parentheses - you only need those when passing an argument to a subroutine if you are using Call or if you are specifically trying to dereference an object - so it would just be:

LayoutControls.SetListBoxColWidths obj

or, with Call (which many regard as obsolete):

Call LayoutControls.SetListBoxColWidths(obj)

Note: when using a Function, you additionally use parentheses if you are using the result of the function.