Outlook Macro to change proofing language of selected text

[Sam Hamels]

Hi everyone,

Using the macro recorder in Word, I created the following macro to change the proofing language of whichever text I currently have selected to English. By assigning a hotkey to this macro (ALT+E), I can now very easily and quickly set the proofing language of some text I select to English, whenever Word is not correctly detecting it as English automatically - instead of having to manually open the 'language proofing menu' every time.

Sub Change_Language_To_English()

    Selection.LanguageID = wdEnglishUK
    Selection.NoProofing = False
    Application.CheckLanguage = False

End Sub

Now I would like to do the same in Windows Outlook desktop 2019, but it lacks a 'record macro' button in the Developer tab. I don't know how to write the correct macro in Outlook-VBA myself - and simply copy-pasting the Word macro in a VBA module in Outlook doesn't seem to work.

Could anyone please suggest what a functioning Outlook macro to set the proofing language of currently selected text to English would look like?

Thanks!
Sam

 

[Sam Hamels]

I found out that this works:

VS Code Outlook 2016 Change e-mail proofing language-VBForums

Currently, I have a VBA code to select e-mail content and change the proofing language. I use a reference to 'Microsoft Word 16.0 Object Library'. Sub Lang(lngLanguage As Word.WdLanguageID) ' "Tools > References > Microsoft Word 16.0 Object Library" needs to be checked Dim...

www.vbforums.com

Sub Lang(lngLanguage As Word.WdLanguageID) 
     ' "Tools > References > Microsoft Word 16.0 Object Library" needs to be checked
    Dim olkItem As Outlook.MailItem, _ 
    wrdDoc As Word.Document, _ 
    wrdSel As Word.Selection 
     
    Set olkItem = Outlook.ActiveInspector.CurrentItem 
    Set wrdDoc = olkItem.GetInspector.WordEditor 
    Set wrdSel = wrdDoc.Windows(1).Selection 
     
    wrdDoc.Bookmarks.Add Range:=wrdSel.Range, Name:="TheTemporarySpellerBookmark" 
     
    With wrdSel 
        .WholeStory 
        .LanguageID = lngLanguage 
        .Shrink 
        .GoTo What:=wdGoToBookmark, Name:="TheTemporarySpellerBookmark" 
    End With 
     
    wrdDoc.Bookmarks("TheTemporarySpellerBookmark").Delete 
    Set wrdSel = Nothing 
    Set wrdDoc = Nothing 
    Set olkItem = Nothing 
End Sub 

Sub AllinENG() 
    Lang (wdEnglishUK) 
End Sub