Outlook Import from Excel

[Fisher1975]

Hi

I have setup and export to outlook for a number of reminders, but I would like to setup some meeting with requires attendees, does anyone know if this is possible?

Many thanks

 

[igold]

Hi Fisher1975,

This will create the Appointment and add Required Attendees, but so far I have been unable to get the appointment to automatically send the invitation.

Sub Appointments()
Const olAppointmentItem As Long = 1
Dim OLApp As Object
Dim OLNS As Object
Dim OLAppointment As Object

On Error Resume Next
Set OLApp = GetObject(, "Outlook.Application")
If OLApp Is Nothing Then Set OLApp = CreateObject("Outlook.Application")
On Error GoTo 0

If Not OLApp Is Nothing Then

Set OLNS = OLApp.GetNamespace("MAPI")
OLNS.Logon

Set OLAppointment = OLApp.CreateItem(olAppointmentItem)

With OLAppointment
      
        .Subject = Range("A1").Value
        .Start = Range("B1").Value                   'Date and Time ie: 5/17/2015  11:45:00 AM
        .Duration = Range("C1").Value               'In minutes
        .body = Range("E1")
        .AllDayEvent = False
        .Location = Range("D1").Value
        .RequiredAttendees = Range("I1").Value
        
        .ReminderSet = True
        .ReminderMinutesBeforeStart = "30"
        .ReminderPlaySound = True
        .ReminderSoundFile = "C:\Windows\Media\Ding.wav"
        
        .display                                              '.save to save
        '.Save
        .send
End With

Set OLAppointment = Nothing
Set OLNS = Nothing
Set OLApp = Nothing
End If

End Sub

HTH

igold