Opening a PDF

[WFS]

Hello,

I'm trying to open a .PDF from Acces using VBA. I have the following code attached to a command buttom :

Private Sub Acrobat_test_Click()
On Error GoTo Err_Acrobat_test_Click

Dim stAppName As String

stAppName = "C:\Program Files\Adobe\Acrobat 4.0\Reader\AcroRd32.exe D:\WINTERTHUR\PFP\PFP Tool\NL\test.pdf"
Call Shell(stAppName, 1)

Exit_Acrobat_test_Click:
Exit Sub

Err_Acrobat_test_Click:
MsgBox Err.Description
Resume Exit_Acrobat_test_Click

End Sub

When clicking the CB, Acrobat opens, but gives the following remarks :
"There was an error opening this document. The file does not exists."
"There was an error opening this document. The path does not exists."

Can anyone help me find and solve the problem...??

WFS

 

[Norie]

I think the problem is the space in the path to the file. Try the following to insert quotation marks around it.

stAppName = "C:\Program Files\Adobe\Acrobat 4.0\Reader\AcroRd32.exe "

stAppName = stAppName & CHR(34) & "D:\WINTERTHUR\PFP\PFP Tool\NL\test.pdf" & CHR(34)

 

[mdmilner]

It probably is as Norie stated (the problem).
However, once I saw this I think it's great. I'd really recommend you use something like this to open PDF's or any files.

http://www.mvps.org/access/api/api0018.htm

'************ Code Start **********
' This code was originally written by Dev Ashish.
' It is not to be altered or distributed,
' except as part of an application.
' You are free to use it in any application,
' provided the copyright notice is left unchanged.
'
' Code Courtesy of
' Dev Ashish
'
Private Declare Function apiShellExecute Lib "shell32.dll" _
    Alias "ShellExecuteA" _
    (ByVal hwnd As Long, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) _
    As Long

'***App Window Constants***
Public Const WIN_NORMAL = 1         'Open Normal
Public Const WIN_MAX = 3            'Open Maximized
Public Const WIN_MIN = 2            'Open Minimized

'***Error Codes***
Private Const ERROR_SUCCESS = 32&
Private Const ERROR_NO_ASSOC = 31&
Private Const ERROR_OUT_OF_MEM = 0&
Private Const ERROR_FILE_NOT_FOUND = 2&
Private Const ERROR_PATH_NOT_FOUND = 3&
Private Const ERROR_BAD_FORMAT = 11&


'***************Usage Examples***********************
'Open a folder:     ?fHandleFile("C:\TEMP\",WIN_NORMAL)
'Call Email app:    ?fHandleFile("mailto:dash10@hotmail.com",WIN_NORMAL)
'Open URL:          ?fHandleFile("http://home.att.net/~dashish", WIN_NORMAL)
'Handle Unknown extensions (call Open With Dialog):
'                   ?fHandleFile("C:\TEMP\TestThis",Win_Normal)
'Start Access instance:
'                   ?fHandleFile("I:\mdbs\CodeNStuff.mdb", Win_NORMAL)
'****************************************************

Public Function fHandleFile(stFile As String, lShowHow As Long)
Dim lRet As Long, varTaskID As Variant
Dim stRet As String
    'First try ShellExecute
    lRet = apiShellExecute(hWndAccessApp, vbNullString, _
            stFile, vbNullString, vbNullString, lShowHow)
            
    If lRet > ERROR_SUCCESS Then
        stRet = vbNullString
        lRet = -1
    Else
        Select Case lRet
            Case ERROR_NO_ASSOC:
                'Try the OpenWith dialog
                varTaskID = Shell("rundll32.exe shell32.dll,OpenAs_RunDLL " _
                        & stFile, WIN_NORMAL)
                lRet = (varTaskID <> 0)
            Case ERROR_OUT_OF_MEM:
                stRet = "Error: Out of Memory/Resources. Couldn't Execute!"
            Case ERROR_FILE_NOT_FOUND:
                stRet = "Error: File not found.  Couldn't Execute!"
            Case ERROR_PATH_NOT_FOUND:
                stRet = "Error: Path not found. Couldn't Execute!"
            Case ERROR_BAD_FORMAT:
                stRet = "Error:  Bad File Format. Couldn't Execute!"
            Case Else:
        End Select
    End If
    fHandleFile = lRet & _
                IIf(stRet = "", vbNullString, ", " & stRet)
End Function