Open Excel from Word - Select and paste data

[FredrikNilsen]

Not sure if this is better posted in a Word VBA forum, but I'll try here first:

I have a Word template, and I want to have a macro to open the file dialogue, select an Excel file, select all data in Sheet1, and copy and paste it to a bookmark ("Data") in the Word template (the data should probably not be linked). I have this code for the first part, but I'm not sure how to approach the rest.

Sub SelectExcelFile()

    Dim xlApp As Excel.Application
    Dim xlWbk As Excel.Workbook
        
    Dim strFile As String
    
    strFile = Excel.Application.GetOpenFilename()
    Workbooks.Open (strFile)
    
    Set xlApp = Excel.Application
    xlApp.Visible = False
        
End Sub

 

[Macropod]

For example, assuming your new document has already been created:

Sub CopyExcelTable()
Application.ScreenUpdating = False
Dim xlApp As Excel.Application, xlWkBk As Excel.Workbook, xlRng As Excel.Range
Dim StrWkBkNm As String, lRow As Long, lCol As Long
With Application.FileDialog(FileDialogType:=msoFileDialogFilePicker)
  .AllowMultiSelect = False
  .Filters.Add "Excel Files", "*.xl*", 1
  .FilterIndex = 1
  'Use Show method to display File Picker dialog box and return user's action
  If .Show = -1 Then
    StrWkBkNm = .SelectedItems(1)
  Else
    Exit Sub
  End If
End With
If UBound(Split(StrWkBkNm, ".xls")) = 0 Then Exit Sub
Set xlApp = CreateObject("Excel.Application")
With xlApp
  .Visible = False
  Set xlWkBk = .Workbooks.Open(FileName:=StrWkBkNm, ReadOnly:=True, AddToMRU:=False)
  With xlWkBk
    With .Sheets(1)
      lRow = .UsedRange.Cells.SpecialCells(xlCellTypeLastCell).Row
      lCol = .UsedRange.Cells.SpecialCells(xlCellTypeLastCell).Column
      Set xlRng = .Range("A1:" & .Cells(lRow, lCol)).Range
      xlRng.Copy
    End With
    .Close False
  End With
  .Quit
End With
ActiveDocument.Bookmarks("Data").Range.Paste
Set xlRng = Nothing: Set xlWkBk = Nothing: Set xlApp = Nothing
Application.ScreenUpdating = True
End Sub