Open all Excel files in folder and save as .xls

[FryGirl]

I have a folder with multiple .xlsm files which I need to programmatically save as .xls file.

Anybody have a vba script to do this?

 

[Joe4]

Here is some code that shows you how to loop through all the files in a specific folder with a specific extension:
https://www.mrexcel.com/forum/excel...sv-files-folder-excel-2011-a.html#post2941307

As far as opening the file, saving it as an "xls" file, and closing the file, you should be able to get the code you need for that by using the Macro Recorder and record yourself doing that step manually.
Then it is just a matter of embedding that code within the loop of the other code.

Give it a try and see how far you get, and if you run into trouble, post the code you have come up with here.

 

[FryGirl]

Thanks Joe, this will work well.

 

[dmt32]

I have a folder with multiple .xlsm files which I need to programmatically save as .xls file.

Anybody have a vba script to do this?

Not fully tested but see if following does what you want:

Sub ChangeFileFormat()
    Dim Folder As String, FileName As String
    Dim wb As Workbook
    
    Folder = "C:\MyFolder\"
    
    FileName = Dir(Folder & "*.xlsm", vbNormal)
    
    On Error GoTo exitsub
    With Application
        .EnableEvents = False: .ScreenUpdating = False
    End With
    Do While FileName <> ""
        
        Set wb = Workbooks.Open(Folder & FileName)
        FileName = Replace(FileName, ".xlsm", ".xls")
        If FileName <> ThisWorkbook.Name Then
            wb.SaveAs FileName:=Folder & FileName, FileFormat:= _
            xlExcel8, Password:="", WriteResPassword:="", _
            ReadOnlyRecommended:=False, CreateBackup:=False
        End If
        
        wb.Close False
        
        FileName = Dir
        Set wb = Nothing
    Loop
exitsub:
    With Application
        .EnableEvents = True: .ScreenUpdating = True
    End With
    If Err > 0 Then MsgBox (Error(Err)), 48, "error"
End Sub

Change folder path / name shown in RED as required.

Dave

 

[FryGirl]

Thanks Joe and Dave. I used a little bit of both and fumbled around until it worked out. Thanks again for your time.