Only stop when left of Decimal Point is changed

[kelly mort]

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    With TextBox1
        If InStr(.Text, ".") > 0 Then
            If Len(Split(.Text, ".")(1)) = [COLOR=#ff0000]2[/COLOR] Then KeyAscii = 0
        End If
        Select Case KeyAscii
            Case Asc("0") To Asc("9")
            Case Asc("."): If UBound(Split(.Text, ".")) = [B][COLOR=#006400]1[/COLOR][/B] Then KeyAscii = 0
            Case Else: KeyAscii = 0
        End Select
    End With
End Sub

Can it be that after the two decimal places achieved I can still change the whole number part part not the DecimalPart?

That's when I am adding to the left part of the ".", allow me.

But to the right, don't.

Thanks

 

[mikerickson]

This code will allow you to enter "123.45"
It will allow you to change the last two digits of that number or to enter numbers before the decimal point.

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    With TextBox1
        If .Text Like "*.*" Then
            If .Text Like "*." Or .Text Like "*.#" Then
                GoSub ValidateNumeric
            Else
                If .SelStart < InStr(1, .Text, ".") Then
                    GoSub ValidateNumeric
                Else
                    If .SelLength > 0 Then
                        GoSub ValidateNumeric
                    Else
                        KeyAscii = 0
                    End If
                End If
            End If
        Else
            If KeyAscii <> Asc(".") Then
                GoSub ValidateNumeric
            End If
        End If
    End With
    If KeyAscii = 0 Then Beep
    Exit Sub
ValidateNumeric:
    Select Case KeyAscii
        Case Is < Asc("0")
            KeyAscii = 0
        Case Is > Asc("9")
        KeyAscii = 0
            Case Else
    End Select
    Return
End Sub

 

[kelly mort]

This code will allow you to enter "123.45"
It will allow you to change the last two digits of that number or to enter numbers before the decimal point.

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    With TextBox1
        If .Text Like "*.*" Then
            If .Text Like "*." Or .Text Like "*.#" Then
                GoSub ValidateNumeric
            Else
                If .SelStart < InStr(1, .Text, ".") Then
                    GoSub ValidateNumeric
                Else
                    If .SelLength > 0 Then
                        GoSub ValidateNumeric
                    Else
                        KeyAscii = 0
                    End If
                End If
            End If
        Else
            If KeyAscii <> Asc(".") Then
                GoSub ValidateNumeric
            End If
        End If
    End With
    If KeyAscii = 0 Then Beep
    Exit Sub
ValidateNumeric:
    Select Case KeyAscii
        Case Is < Asc("0")
            KeyAscii = 0
        Case Is > Asc("9")
        KeyAscii = 0
            Case Else
    End Select
    Return
End Sub

Great !!!!


More than enough.

Thanks