only alphanumeric

[paran]

Hi,

I have a userform that has a number of textboxes that I need to restrict to allow only alphanumeric characters. Letters / numbers only.

No / * . characters etc.

Is this to be done using vba code, if so, can anyone help with what the code would be and where to put it.

like TEXU1234567
CAXU1234567

Thanks in advance.

 

[maabadi]

Go and Check this Thread and Reply by @Rick Rothstein

Userform Textbox - prevent special characters​

 

[Akuini]

I have a userform that has a number of textboxes that I need to restrict to allow only alphanumeric characters. Letters / numbers only.

No / * . characters etc.

Here's an option:

Private Sub TextBox1_Change()
With TextBox1
    If Not toValid(TextBox1) Then Beep: .Text = Left(.Text, Len(.Text) - 1)
End With
End Sub


Function toValid(obj As Object) As Boolean
'accept only alphanumeric char (unspecified length)
Dim x As Long
Dim tx As String
toValid = True
tx = "[a-zA-Z0-9]"
    With obj
        x = Len(.Text)
        If x > 0 Then
            If Not .Text Like WorksheetFunction.Rept(tx, x) Then toValid = False
        End If
    End With
End Function

like TEXU1234567
CAXU1234567

Your example shows a pattern i.e 4 capital letter followed by 7 number.
If you want to restrict input by that pattern:

Private Sub TextBox2_Change()
With TextBox2
    If Not xPattern(TextBox2) Then Beep: .Text = Left(.Text, Len(.Text) - 1)
End With
End Sub

Function xPattern(obj As Object) As Boolean
'PATTERN: 4 capital letter followed by 7 number
'TEXU1234567 CAXU1234567
Dim x As Long
Dim tx As String
xPattern = True
tx = "[A-Z]"
    With obj
        x = Len(.Text)
        Select Case x
            Case 0
                Exit Function
            Case 1 To 4
                If Not .Text Like WorksheetFunction.Rept(tx, x) Then xPattern = False
            Case 5 To 11
                If Not Mid(.Text, 5) Like WorksheetFunction.Rept("#", x - 4) Then xPattern = False
            Case Is > 11
                xPattern = False
        End Select

    End With
End Function

 

[Sektor]

Function HasValidCharacters(text$) As Boolean
    With CreateObject("VBScript.RegExp")
        .Global = True: .IgnoreCase = True: .Pattern = "^[a-z0-9]+$"
        HasValidCharacters = .Test(text)
    End With
End Function

 

[paran]

Here's an option:

Private Sub TextBox1_Change()
With TextBox1
    If Not toValid(TextBox1) Then Beep: .Text = Left(.Text, Len(.Text) - 1)
End With
End Sub


Function toValid(obj As Object) As Boolean
'accept only alphanumeric char (unspecified length)
Dim x As Long
Dim tx As String
toValid = True
tx = "[a-zA-Z0-9]"
    With obj
        x = Len(.Text)
        If x > 0 Then
            If Not .Text Like WorksheetFunction.Rept(tx, x) Then toValid = False
        End If
    End With
End Function

Your example shows a pattern i.e 4 capital letter followed by 7 number.
If you want to restrict input by that pattern:

Private Sub TextBox2_Change()
With TextBox2
    If Not xPattern(TextBox2) Then Beep: .Text = Left(.Text, Len(.Text) - 1)
End With
End Sub

Function xPattern(obj As Object) As Boolean
'PATTERN: 4 capital letter followed by 7 number
'TEXU1234567 CAXU1234567
Dim x As Long
Dim tx As String
xPattern = True
tx = "[A-Z]"
    With obj
        x = Len(.Text)
        Select Case x
            Case 0
                Exit Function
            Case 1 To 4
                If Not .Text Like WorksheetFunction.Rept(tx, x) Then xPattern = False
            Case 5 To 11
                If Not Mid(.Text, 5) Like WorksheetFunction.Rept("#", x - 4) Then xPattern = False
            Case Is > 11
                xPattern = False
        End Select

    End With
End Function

thanks dear ,appreciate your response and it worked

 

[Rick Rothstein]

I see you marked a UDF (user defined function) as the Answer. If that is all you were after, that function can be written using only one line of code...

Function HasValidCharacters(S As String) As Boolean
  HasValidCharacters = Not S Like "*[!A-Za-z0-9]*"
End Function