Offset values not being entered into spreadsheet

[Pookiemeister]

I not sure why the below code is not adding my userform entries to the spreadsheet. I did a CompileVBAProject test and there were no issues. I stepped through the program and no error messages appeared. What this program is suppose to do is it will find the final row with a value in it and add one to find the first empty row. Then it will make it the Selected ActiveCell if it is empty.

Starting with that cell, it will start adding values to the spreadsheet from the userform or it supposed to add values but it doesn't. Thank You

Private Sub cmdbtnAddItem_Click()    
    Dim FinalRow As Integer, x As Integer


    Worksheets("IMA").Select


    FinalRow = Cells(Rows.Count, 2).End(xlUp).Row
    
        x = FinalRow + 1
        Cells(x, 2).Select
        If Cells(x, 2).Value = "" Then
            ActiveCell.Select
        Else
            Selection.End(xlUp).Offset(1, 0).Row
        End If
        
        ActiveCell.Offset(x, 2).Value = frmAddProduct.txtbxPrdctCde.Value
        ActiveCell.Offset(x, 3).Value = frmAddProduct.txtbxDescription.Value
        ActiveCell.Offset(x, 4).Value = Me.txtbxDzPrCs.Value
        ActiveCell.Offset(x, 5).Value = Me.txtbxCsPerPal.Value
        ActiveCell.Offset(x, 7).Value = Me.txtbxStckNum.Value
       

End Sub

 

[Logit]

.
You really don't need to use the Offset command to accomplish your goal. Review this macro :

Option Explicit


Private Sub btnOK_Click()
    Dim ws As Worksheet
    Set ws = ActiveSheet
    Dim newRow As Long
    
    'next line checks Col A for first blank cell after last used
    newRow = Application.WorksheetFunction.CountA(ws.Range("A:A")) + 1
    
    ws.Cells(newRow, 1).Value = Me.txtbxPrdctCde.Value          'write to Col A
    ws.Cells(newRow, 2).Value = Me.txtbxDescription.Value       'writes to Col B
    ws.Cells(newRow, 3).Value = Me.txtbxDzPrCs.Value            'wrotes to Col C
    ws.Cells(newRow, 4).Value = Me.txtbxCsPerPal.Value          'writes to Col D
    ws.Cells(newRow, 5).Value = Me.txtbxStckNum.Value           'writes to Col E
    
End Sub

As the comments indicate ... the values from the textboxes in your UserForm are written to the first blank row, beginning in Col A.
If you really want the data to shift one column to the right (begin writing to Col B), edit ws.Cells(newRow, 1).Value to ws.Cells(newRow, 2).Value
and edit the remainder to the next higher number as well.

 

[My Aswer Is This]

Your script should look something like this.
Never a good plan to use active cell.

My Controls have different names.

Private Sub cmdbtnAddItem_Click()
'Modified  9/12/2018  10:19:06 PM  EDT
Worksheets("IMA").Select
Dim Lastrow As Long
Lastrow = Cells(Rows.Count, "B").End(xlUp).Row + 1
            
        Cells(Lastrow, 2).Value = TextBox1.Value
        Cells(Lastrow, 3).Value = TextBox2.Value
        Cells(Lastrow, 4).Value = TextBox3.Value
        Cells(Lastrow, 5).Value = TextBox4.Value
        Cells(Lastrow, 7).Value = TextBox5.Value
End Sub