OFFSET for incrementing formula 3 columns?

[slam]

I have this formula that I need to copy across multiple columns, but I need to increment the references by 3 columns each time.

=1-(SUM('Tracking Compliance Data'!J3:J252)/(SUM('Tracking Compliance Data'!I3:I252)))

So in the next formula, J3 becomes M3, and so on. I think I need to use OFFSET, but am struggling to put it together. Any help would be greatly appreciated!

Thanks

 

[MagnarH]

If I understood correctly:
For the J formula:

SUM(OFFSET('Tracking Compliance Data'!$A$1,3,COLUMN(C1)*3,250,1))

For the I formula (if you want that move as well):

SUM(OFFSET('Tracking Compliance Data'!$A$1,3,COLUMN(C1)*3-1,250,1))

 

[hagia_sofia]

Maybe something like:

=1-(CHOOSECOLS(BYCOL('Tracking Compliance Data'!I3:T252,LAMBDA(x,SUM(x))),SEQUENCE(4,,2,3))/CHOOSECOLS(BYCOL('Tracking Compliance Data'!I3:T252,LAMBDA(x,SUM(x))),SEQUENCE(4,,1,3)))

 

[slam]

If I understood correctly:
For the J formula:

SUM(OFFSET('Tracking Compliance Data'!$A$1,3,COLUMN(C1)*3,250,1))

For the I formula (if you want that move as well):

SUM(OFFSET('Tracking Compliance Data'!$A$1,3,COLUMN(C1)*3-1,250,1))

Thank you, I did need both, so have added it as this:

=1-SUM(OFFSET('Tracking Compliance Data'!$A$1,3,COLUMN(C1)*3,252,1))/SUM(OFFSET('Tracking Compliance Data'!$A$1,3,COLUMN(C1)*3-1,252,1))

At first glance, it looked like it was working. However, to confirm, I did the same calculation on two of the columns, for example, as =1-(AQ105/AP105). This gave me 80.9524%, but the formula is giving me 80.8443%. I checked the others, and they seem to all be off by a little bit, up to 2%

Did I do something wrong? My data starts in row 3, and the first columns containing data for the formula are I & J.

Thanks!

EDIT: Ah, figured it out. Needed to change the row reference to +2 instead of +3. Working now!

=1-SUM(OFFSET('Tracking Compliance Data'!$A$1,2,COLUMN(C1)*3,252,1))/SUM(OFFSET('Tracking Compliance Data'!$A$1,2,COLUMN(C1)*3-1,252,1))