Object Variable or With Block Variable Not Set Error

[NorthbyNorthwest]

Hi, everyone. Could someone please tell me why I get an "object variable or with block variable not set" error when I run this code? Note: I do not get an error on first run of line. But I do get it on second run (line in green text). What do I have wrong?

Sub ShuffleBoard()
Dim ws As Worksheet
Dim RowNum As Long
Dim ReturnRowNum As Long
Dim SearchRange As Range
Dim rng As Range
Dim rng1 As Range
Dim FindRow As Range

Call ShowCalculator

Worksheets("Assignments").Activate
Set ws = Worksheets("Assignments")

Set SearchRange = ws.Range("AP6:AP52")
Set FindRow = SearchRange.Find("Auditor", LookIn:=xlValues, LookAt:=xlWhole)

    If Not FindRow Is Nothing Then ReturnRowNum = FindRow.Row
    RowNum = FindRow.Row
    
    Set rng = ws.Range("AP6")
    rng.Cut
    ws.Range(Cells(RowNum, 42), Cells(RowNum, 42)).Insert Shift:=xlDown
    
Set SearchRange = ws.Range("M8:V39")
Set FindRow = SearchRange.Find("Auditor", LookIn:=xlValues, LookAt:=xlWhole)

    If Not FindRow Is Nothing Then ReturnRowNum = FindRow.Row
  [COLOR=rgb(65, 168, 95)]  RowNum = FindRow.Row[/COLOR]

    Set rng1 = ws.Range("M8")
    rng1.Cut
    ws.Range(Cells(RowNum, 13), Cells(RowNum, 13)).Insert Shift:=xlDown

Range("AN1").Select
End Sub

 

[DanteAmor]

I do not get an error on first run of line. But I do get it on second run

The second run searches in another range.

Try this way:

Sub ShuffleBoard()
  Dim ws As Worksheet
  Dim RowNum As Long
  Dim SearchRange As Range, rng As Range, rng1 As Range, FindRow As Range
 
  Call ShowCalculator
  Set ws = Worksheets("Assignments")
 
  Set SearchRange = ws.Range("AP6:AP52")
  Set FindRow = SearchRange.Find("Auditor", LookIn:=xlValues, LookAt:=xlWhole)
  If Not FindRow Is Nothing Then
    RowNum = FindRow.Row
    Set rng = ws.Range("AP6")
    rng.Cut
    ws.Range(ws.Cells(RowNum, 42), ws.Cells(RowNum, 42)).Insert Shift:=xlDown
  Else
    MsgBox "The word Auditor does not exist in the range 'AP6:AP52'"
  End If
 
  Set SearchRange = ws.Range("M8:V39")
  Set FindRow = SearchRange.Find("Auditor", LookIn:=xlValues, LookAt:=xlWhole)
  If Not FindRow Is Nothing Then
    RowNum = FindRow.Row
    Set rng1 = ws.Range("M8")
    rng1.Cut
    ws.Range(ws.Cells(RowNum, 13), ws.Cells(RowNum, 13)).Insert Shift:=xlDown
  Else
    MsgBox "The word Auditor does not exist in the range 'M8:V39'"
  End If

  Range("AN1").Select
End Sub

NOTES:
To put color in the code, you must use the "RICH code" icon:

You must also use the sheet reference in each cell or range object:

ws.Range(ws.Cells(RowNum, 42), ws.Cells(RowNum, 42)).Insert Shift:=xlDown

 

[NorthbyNorthwest]

Thanks so much for the help. Have a great day!