Object variable or With block variable not set error???

[Disgruntled77]

Good day all,

I have reached the end of my own limited knowledge and ask if anyone here could help me?

I have a simple spreadsheet, column(5) "E", has a pulldown with values P1 thru P4. The following code simply places an 'X' in column "A" when P1 is selected, and removes the 'X' when any other value is chosen.

My problem is when any other cell is edited, I receive a 'Object variable or With block variable not set error'...

Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo Whoa
    If Target.Cells.CountLarge > 1 Then Exit Sub
      Application.EnableEvents = False
    
    If Intersect(Target, Columns(5)) = "P1" Then
      If Target.Row > 1 Then
        Range("A" & Target.Row).Value = "X"
    End If
      End If
    
    If Not Intersect(Target, Columns(5)) = "P1" Then
      If Target.Row > 1 Then
            Range("A" & Target.Row).Value = ""
    End If
      End If
             
Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub

Any help is greatly appreciated.

Sincerely,
Ryan

 

[Fluff]

Hi & welcome to MrExcel
Try

Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo Whoa
    If Target.Cells.CountLarge > 1 Then Exit Sub
      Application.EnableEvents = False
    
    If Not Intersect(Target, Columns(5)) Is Nothing Then
      If Target.Row > 1 Then
        Range("A" & Target.Row).Value = IIf(Target.Value = "P1", "X", "")
      End If
   End If
Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub

 

[Richard U]

You need to include for the condition where there is no intersect.

You get the error because you try to do a logical check on a range (which is the intersect) where the range is nothing.

That's what it means. I added code to check to see if the intersect is nothing, and if so, exit the codee

Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo Whoa
    If Intersect(Target, Columns(5)) Is Nothing Then Exit Sub
    If Target.Cells.CountLarge > 1 Then Exit Sub
      Application.EnableEvents = False

    
    If Intersect(Target, Columns(5)) = "P1" Then
      If Target.Row > 1 Then
        Range("A" & Target.Row) = "X"
    End If
      End If
    
    If Not Intersect(Target, Columns(5)) = "P1" Then
      If Target.Row > 1 Then
            Range("A" & Target.Row).Value = ""
    End If
      End If
             
Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub