Not match criteria: Will using * or + in formulas slow my workbook?

[danhendo888]

For example, I am extracting Codes from column B that are not WHEEL and TYRE, where:
- Column A must be = TESLA
- Column C must be = R

So the output should be = OIL, GAS

For this desired output, is it possible to not use direct operators or is this an example where it would be necessary/unavoidable?

Book1
	A	B	C	D	E	F	G	H
1	Data:					My Sheet		Output
2	Model	Code	Revenue or Expense			Exclude These -->	WHEEL
3	Tesla	WHEEL	R				TYRE
4	Ford	OIL	E
5	Ford	TYRE	E			Output using *	Tesla	OIL
6	Tesla	TYRE	R					GAS
7	Tesla	DEALER	E
8	Tesla	OIL	R
9	Tesla	GAS	R
10						Output using +	Tesla	OIL
11								GAS
Sheet1

Cell Formulas
Range	Formula
H5:H6	H5	=FILTER(FILTER(B3:B9,(A3:A9=G5)*(C3:C9="R")),ISNA(XMATCH(FILTER(B3:B9,(A3:A9=G5)*(C3:C9="R")),G2:G3)))
H10:H11	H10	=FILTER(FILTER(B3:B9,(A3:A9=G5)+(C3:C9="R")=2),ISNA(XMATCH(FILTER(B3:B9,(A3:A9=G5)+(C3:C9="R")=2),G2:G3)))
Dynamic array formulas.

 

[Alex Blakenburg]

I can't see that you will be able to avoid it given the scenario, but you can lessen the impact by not Filtering the whole range multiple times by using Let.
Multiplication:

=LET(RevMod,FILTER(B3:B9,(A3:A9=G5)*(C3:C9="R")),
             FILTER(RevMod,ISNA(XMATCH(RevMod,G2:G3))))

Addition:

=LET(RevMod,FILTER(B3:B9,(A3:A9=G5)+(C3:C9="R")=2),
             FILTER(RevMod,ISNA(XMATCH(RevMod,G2:G3))))

 

[Phuoc]

Another option:

=FILTER(B3:B9,(A3:A9=G5)*(C3:C9="R")*(COUNTIF(G2:G3,B3:B9)=0))

 

[Fluff]

Another option

=FILTER(B3:B9,(A3:A9=G5)*(C3:C9="R")*(ISNA(XMATCH(B3:B9,G2:G3))))