NETWORKDAYS and Different workdays

[albasheer]

Hello,

I am using the NETWORKDAYS function. Is there a simple way to have working days changed from Monday-Friday to Sunday-Thursday?

I know it can be done using sumproduct and an array, but I thought maybe there would be an easier way.

Thanks.

 

[xld]

Add one to each date

=NETWORKDAYS(A4+1,A8+1)

 

[albasheer]

Add one to each date

=NETWORKDAYS(A4+1,A8+1)

Thanks xld. What if there were only one weekend day, Friday for instance?

 

[xld]

If you don't have to worry about holidays

SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(A3&":"&A9)))={1,2,3,4,5,7}))

 

[albasheer]

Thanks, xld. Very helpful!

 

[barry houdini]

You can also count all Fridays between A2 and B2 with this formula

=INT((WEEKDAY(A2-6)+B2-A2)/7)

so to count all non-Fridays in the range....

=B2-A2+1-INT((WEEKDAY(A2-6)+B2-A2)/7)

or like this.....

=SUM(INT((WEEKDAY(A2-{1,2,3,4,5,7})+B2-A2)/7))

 

[albasheer]

Great! This way I can build the sheet to allow for many possibilities by adjusting the formula to calculate all Fridays and/or all Saturdays, and then a count of holidays in a year to build different scenarios. Thanks.