Nesting Multiple Tests Of MkDir's?

[Lewzerrrr]

Hi,

If I wanted to test if any of these filepaths exist and if not to create, what would be the simplest way to nest create? e.g. S:\Folder1\Folder2\Folder3\Folder4

What I've been using is.. but can it be shortened?

If Len(Dir("S:\Folder1\", vbDirectory)) = 0 Then    
    MkDir ("S:\Folder1\"
End If


If Len(Dir("S:\Folder1\Folder2\", vbDirectory)) = 0 Then
    MkDir ("S:\Folder1\Folder2\")
End If


If Len(Dir("S:\Folder1\Folder2\Folder3\", vbDirectory)) = 0 Then
    MkDir ("S:\Folder1\Folder2\Folder3\")
End If


If Len(Dir("S:\Folder1\Folder2\Folder3\Folder4\", vbDirectory)) = 0 Then
    MkDir ("S:\Folder1\Folder2\Folder3\Folder4\")
End If

 

[dmt32]

Hi
try this

in a standard module:

Sub MakeDirectory(ByVal FolderPath As String)
    Dim SubFolders As Variant
    Dim MakeFolder As String
    Dim i As Integer
    
    SubFolders = Split(FolderPath, "\")
    
    For i = 0 To UBound(SubFolders)
        Select Case i
        Case 0
            MakeFolder = SubFolders(i) & "\"
        Case 1
            MakeFolder = MakeFolder & SubFolders(i)
        Case Else
            MakeFolder = MakeFolder & "\" & SubFolders(i)
        End Select
        
        If Dir(MakeFolder, vbDirectory) = vbNullString Then MkDir MakeFolder
    Next
End Sub

to call it:

MakeDirectory "S:\Test\Folder1\Folder2\Folder3\Folder4"

Dave

 

[Lewzerrrr]

Hi
try this

in a standard module:

Sub MakeDirectory(ByVal FolderPath As String)
    Dim SubFolders As Variant
    Dim MakeFolder As String
    Dim i As Integer
    
    SubFolders = Split(FolderPath, "\")
    
    For i = 0 To UBound(SubFolders)
        Select Case i
        Case 0
            MakeFolder = SubFolders(i) & "\"
        Case 1
            MakeFolder = MakeFolder & SubFolders(i)
        Case Else
            MakeFolder = MakeFolder & "\" & SubFolders(i)
        End Select
        
        If Dir(MakeFolder, vbDirectory) = vbNullString Then MkDir MakeFolder
    Next
End Sub

to call it:

MakeDirectory "S:\Test\Folder1\Folder2\Folder3\Folder4"

Dave

Thanks Ill give that a try, I've also come up with error handling it instead such as:

On Error Resume Next
MkDir("S:\Folder1\")
MkDir("S:\Folder1\Folder2\")
MkDir("S:\Folder1\Folder2\Folder3\")
On Error GoTo 0

What's the downside to this?