Nest two IF statements

[kuhfku]

I have the following IF statements in a spreadsheet for tracking observations. Cell C11 is the date of the observation. The nested IF statement is intended to go in a "next observation due" column.

=IF(ISNUMBER(SEARCH("walkthrough",D11)),WORKDAY(C11,10),WORKDAY(C11,40))

=IF(OR(C11="",E11="Ungraded",L11="Yes"),"",WORKDAY(C11,10,))

The first statement is to add 10 working days to C11 if cell D11 contains the word walkthrough, if not it adds 40 working days.

The second statement will blank the cell if no observation has taken place (C11), the observation was ungraded (E11) or the actions have been achieved (L11), if not it adds 10 working days to C11.

Both statements work on their own but I need them both to work in the same cell and I can't make them nest and still work. I just get a #VALUE error when I attempt to nest them.

I have tried the following:

=IF(ISNUMBER(SEARCH("walkthrough",D11)),WORKDAY(C11,10),WORKDAY(C11,40)), IF(OR(C11="",L11="Yes",E11="Ungraded"),"",WORKDAY(C11,10,))

=IF(OR(C11="",L11="Yes",E11="Ungraded"),"",WORKDAY(C11,10,)), IF(ISNUMBER(SEARCH("walkthrough",D11)),WORKDAY(C11,10),WORKDAY(C11,40))

=IF(OR(C11="",L11="Yes",E11="Ungraded"),""), IF(ISNUMBER(SEARCH("walkthrough",D11)),WORKDAY(C11,10),WORKDAY(C11,40))

=IF(ISNUMBER(SEARCH("walkthrough",D11)),WORKDAY(C11,10),WORKDAY(C11,40)), IF(OR(C11="",L11="Yes",E11="Ungraded"),"")

I basically ran out of ideas at that point. Is there a way to merge these statements? Or is there just a simpler way to do it?

Thanks

 

[Swapnil Shah]

Re: Struggling to nest two IF statements

Try Following

=IF(OR(C11="",E11="Ungraded",L11="Yes"),"",IF(NOT(ISNUMBER(SEARCH("walkthrough",D11))),WORKDAY(C11,40),WORKDAY(C11,10)))

Thanks
Swapnil Shah

 

[kuhfku]

Re: Struggling to nest two IF statements

That's done it. Thanks!!