Need help with input box

[TsarMarkI]

Good Afternoon all,

I have a VBA macro that allows for data being entered into a text box to be placed in specific areas of my sheet. However, when I click "OK" with no value entered (blank), it ends the sub. I need the sub to stop running when it finds a blank value on the sheet, but when no value is entered into the text box, I need it to be recognized as a "0" value.

I would also like the sub to pick up where the data left off should the sub be ended early (this isn't a requirement for the sheet)

Also, I need the "Cancel" button in the input box to end the sub completely. Any help would be incredibly appreciated; current sub below:

Sub Test()
'
Dim Cl As Range
Dim Res As Variant
Dim i As Long
Dim wks As Worksheet

Application.ScreenUpdating = False

For Each wks In ActiveWorkbook.Worksheets
wks.Visible = xlSheetVisible
Next wks

Sheets("Test").Select


For Each Cl In Range("F2", Range("F" & Rows.Count).End(xlUp))
For i = 1 To 2
Res = InputBox("Please enter the total quantity in " & Cl.Value)
If Cl.Value = "" Then MsgBox "No More Cycle Counts Available"
If Res = "" Then Call Hide
If Res = "" Then Exit Sub
Cl.Offset(, -2).Value = Val(Res)
If Val(Res) = Cl.Offset(, -3).Value Then Exit For
Next i
Next Cl

Application.ScreenUpdating = True

End Sub

 

[Yongle]

It is not a textbox - it's an input box (using the correct terminology reduces confusion )

Immediately below
​

Res = InputBox ...

insert this line

If Res = "" Then Res = 0

 

[TsarMarkI]

Thanks Yongle! Sorry about that- totally meant to keep "InputBox" as consistent as possible. The change works great for accepting blank values as zero, but now I have to run through the entire list it's referencing in order to end the macro (I believe it's also treating the "Cancel" button as zero)

 

[TsarMarkI]

Nevermind, I figured it out based on where you started me. Cheers!

 

[Yongle]

It is always better to "figure it out" - you are more likely to remember

 

[Rick Rothstein]

Nevermind, I figured it out based on where you started me. Cheers!

I am glad you figured it out, but thought you might like to see this anyway. Here is a generalized structure you can use for the InputBox that will allow you to react to the user clicking the Cancel button or clicking Enter without filling in anything as well as when the user enters actual data...

Dim Answer As String
 '....
 Answer = InputBox("Tell me something")
 If StrPtr(Answer) = 0 Then
   MsgBox "The user clicked Cancel, so we will exit the subroutine now."
   Exit Sub
 ElseIf Len(Answer) = 0 Then
   MsgBox "The user clicked OK without entering anything in the InputBox!"
 Else
   MsgBox "The user entered the following..." & vbLf & vbLf & Answer
 End If