Need all unique combinations of a single column

[Goldheart]

I need to create a list of unique name combinations from a single column, for example:

Mary
Jim
Henry
Candy

And output all unique combinations but also grouped up to the number of names. E.G. Mary + Jim, Mary + Jim + Henry, etc. The name column may vary in total names. Perhaps output one column with pairs, one with triples, quads, etc.

Thank you for any assistance!

 

[JamesCanale]

I don't think that 2016 has the Concat function. This might be trouble.

MrExcelPlayground5.xlsx
	A	B	C
3	Mary	1	Mary
4	Jim	2	Jim
5	Henry	3	Mary Jim
6	Candy	4	Henry
7		5	Mary Henry
8		6	Jim Henry
9		7	Mary Jim Henry
10		8	Candy
11		9	Mary Candy
12		10	Jim Candy
13		11	Mary Jim Candy
14		12	Henry Candy
15		13	Mary Henry Candy
16		14	Jim Henry Candy
17		15	Mary Jim Henry Candy
18		16
Sheet20

Cell Formulas
Range	Formula
B3:B18	B3	=ROW(INDIRECT("1:"&2^COUNTA(A3:A29)))
C3:C18	C3	=CONCAT(IF(BITAND(B3,(2^(ROW(INDIRECT("1:"&COUNTA($A$3:$A$20)))-1)))>0,INDEX($A$3:$A$20,ROW(INDIRECT("1:"&COUNTA($A$3:$A$20)))) & " ",""))
Dynamic array formulas.

 

[Eric W]

Here's a macro version. Starting with

Book1
	A
1	Names
2	Mary
3	Jim
4	Henry
5	Candy
6
Sheet15

Run this macro:

Sub Subsets()
Dim MyNames As Variant, OutCell As Range, MyDic As Object, i As Long

    MyNames = Range(Range("A2"), Range("A2").End(xlDown)).Value
    Set OutCell = Range("C1")
    
    For i = 1 To UBound(MyNames)
        Set MyDic = CreateObject("Scripting.Dictionary")
        MyDic(0) = "Sets of " & i
        Call RecurSubs(MyNames, i, 0, 0, "", MyDic)
        OutCell.Offset(, i - 1).Resize(MyDic.Count).Value = WorksheetFunction.Transpose(MyDic.items)
        Set MyDic = Nothing
    Next i
    
End Sub

Sub RecurSubs(ByRef MyNames, ByRef MaxLevel, ByVal CurLevel, ByVal ix, ByVal str1, ByRef MyDic)
Dim i As Long

    If CurLevel = MaxLevel Then
        MyDic(MyDic.Count) = Left(str1, Len(str1) - 2)
        Exit Sub
    End If
    
    For i = ix + 1 To UBound(MyNames)
        Call RecurSubs(MyNames, MaxLevel, CurLevel + 1, i, str1 & MyNames(i, 1) & ", ", MyDic)
    Next i
    
End Sub

And you'll get this:

Book1
	A	B	C	D	E	F
1	Names		Sets of 1	Sets of 2	Sets of 3	Sets of 4
2	Mary		Mary	Mary, Jim	Mary, Jim, Henry	Mary, Jim, Henry, Candy
3	Jim		Jim	Mary, Henry	Mary, Jim, Candy
4	Henry		Henry	Mary, Candy	Mary, Henry, Candy
5	Candy		Candy	Jim, Henry	Jim, Henry, Candy
6				Jim, Candy
7				Henry, Candy
8
Sheet15

It adjusts for a variable number of names. You can set the input cell (A2) in the top line of the macro, and the output starting cell (C1) in the next line.

 

[Goldheart]

Here's a macro version. Starting with

Book1
	A
1	Names
2	Mary
3	Jim
4	Henry
5	Candy
6
Sheet15

Run this macro:

Sub Subsets()
Dim MyNames As Variant, OutCell As Range, MyDic As Object, i As Long

    MyNames = Range(Range("A2"), Range("A2").End(xlDown)).Value
    Set OutCell = Range("C1")
   
    For i = 1 To UBound(MyNames)
        Set MyDic = CreateObject("Scripting.Dictionary")
        MyDic(0) = "Sets of " & i
        Call RecurSubs(MyNames, i, 0, 0, "", MyDic)
        OutCell.Offset(, i - 1).Resize(MyDic.Count).Value = WorksheetFunction.Transpose(MyDic.items)
        Set MyDic = Nothing
    Next i
   
End Sub

Sub RecurSubs(ByRef MyNames, ByRef MaxLevel, ByVal CurLevel, ByVal ix, ByVal str1, ByRef MyDic)
Dim i As Long

    If CurLevel = MaxLevel Then
        MyDic(MyDic.Count) = Left(str1, Len(str1) - 2)
        Exit Sub
    End If
   
    For i = ix + 1 To UBound(MyNames)
        Call RecurSubs(MyNames, MaxLevel, CurLevel + 1, i, str1 & MyNames(i, 1) & ", ", MyDic)
    Next i
   
End Sub

And you'll get this:

Book1
	A	B	C	D	E	F
1	Names		Sets of 1	Sets of 2	Sets of 3	Sets of 4
2	Mary		Mary	Mary, Jim	Mary, Jim, Henry	Mary, Jim, Henry, Candy
3	Jim		Jim	Mary, Henry	Mary, Jim, Candy
4	Henry		Henry	Mary, Candy	Mary, Henry, Candy
5	Candy		Candy	Jim, Henry	Jim, Henry, Candy
6				Jim, Candy
7				Henry, Candy
8
Sheet15

It adjusts for a variable number of names. You can set the input cell (A2) in the top line of the macro, and the output starting cell (C1) in the next line.

Perfect! Works great thank you!

 

[Goldheart]

By the way, I think we have the same or similar name. I am Eric West.

 

[Eric W]

Glad we could help!

Nope, not West, but close.