Need a VBA Macro to hide/ unhide rows based on a string in a cell value

[vipin30sep]

I have a column (A) that has below values in different cells (A1, A2 and A3 and so on).

PPC Revenue - 2015
Non-PPC Revenue - 2015
ROAS - <Enter PPC 1 Name> - 2015
ROAS - <Enter PPC 1 Name> - 2017
Non-PPC Revenue - 2016
Non-PPC Revenue - 2020

I need a macro that can be used to hide/ unhide rows based on the condition - If the value is 2015 it should hide the rows that have 2015 in it (along with other text), so basically, using the macro i should be able to hide all 3 rows (above) as it has 2015 in it. Please assist. Appreciate your help!

 

[My Aswer Is This]

Try this:

Sub Hide_Rows()
'Modified 7/17/2019 8:38:16 PM  EDT
Application.ScreenUpdating = False
Dim i As Long
Dim Lastrow As Long
Lastrow = Cells(Rows.Count, "A").End(xlUp).Row
For i = Lastrow To 1 Step -1
If InStr(Cells(i, 1).Value, "2015") Then Rows(i).Hidden = True
Next
Application.ScreenUpdating = True
End Sub

 

[My Aswer Is This]

Now if your saying you want to toggle them from hidden to not hidden use this script.

Sub Hide_Rows()
'Modified  7/17/2019  8:49:01 PM  EDT
Application.ScreenUpdating = False
Dim i As Long
Dim Lastrow As Long
Lastrow = Cells(Rows.Count, "A").End(xlUp).Row
For i = Lastrow To 1 Step -1
If InStr(Cells(i, 1).Value, "2015") Then Rows(i).Hidden = Not Rows(i).Hidden
Next
Application.ScreenUpdating = True
End Sub

 

[My Aswer Is This]

If you want to choose what year then use this script:

Sub Hide_Rows()
'Modified  7/17/2019  9:42:18 PM  EDT
Application.ScreenUpdating = False
Dim i As Long
Dim Lastrow As Long
Dim ans As String
ans = InputBox("Enter Year", "Enter Year like this 2015", Format(Date, "YYYY"))
Lastrow = Cells(Rows.Count, "A").End(xlUp).Row
For i = Lastrow To 1 Step -1
If InStr(Cells(i, 1).Value, ans) Then Rows(i).Hidden = Not Rows(i).Hidden
Next
Application.ScreenUpdating = True
End Sub

 

[vipin30sep]

Awesome! It works. Appreciate your help.

If you want to choose what year then use this script:

Sub Hide_Rows()
'Modified  7/17/2019  9:42:18 PM  EDT
Application.ScreenUpdating = False
Dim i As Long
Dim Lastrow As Long
Dim ans As String
ans = InputBox("Enter Year", "Enter Year like this 2015", Format(Date, "YYYY"))
Lastrow = Cells(Rows.Count, "A").End(xlUp).Row
For i = Lastrow To 1 Step -1
If InStr(Cells(i, 1).Value, ans) Then Rows(i).Hidden = Not Rows(i).Hidden
Next
Application.ScreenUpdating = True
End Sub

 

[My Aswer Is This]

Glad I was able to help you.
Come back here to Mr. Excel next time you need additional assistance.

Awesome! It works. Appreciate your help.