Multiple Sort - move columns in order

[techgirl]

I have a file that has Row AND Column titles. Both are out of order and both need to be sorted, and being able to keep the data together.
I would like to have the Names in column one in alphabetical order, as well as the Client names in alphbetical order. I have over 60 columns and don't want to have to drag and drop in order.

	Client 3	Client 1	Client 10	Client 2
Bob	5-Mar-22​	1-Jan-22​	2-Feb-22​	1-Jan-22​
Sandy	10-Feb-22​	6-Mar-22​	2-Mar-22​	1-Jan-22​
Eric	5-Jan-22​	1-Mar-22​	15-Jan-22​	5-Jan-22​
Autumn	2-Feb-22​	11-Feb-22​	2-Feb-22​	2-Feb-22​
Andrew	1-Jan-22​	5-Mar-22​	10-Feb-22​	5-Mar-22​

 

[John_w]

Try this macro:

Public Sub Sort_Rows_and_Columns()

    Dim lastCol As Long, lastRow As Long
    Dim colsRange As Range, rowsRange As Range
    
    With ThisWorkbook.ActiveSheet
    
        lastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        lastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
        Set colsRange = .Range("B1").Resize(lastRow, lastCol - 1)
        Set rowsRange = .Range("A2").Resize(lastRow - 1, lastCol)
    
        'Sort columns
    
        .Sort.SortFields.Clear
        .Sort.SortFields.Add2 Key:=colsRange.Resize(1), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        With .Sort
            .SetRange colsRange
            .Header = xlYes 'xlGuess
            .MatchCase = False
            .Orientation = xlLeftToRight
            .SortMethod = xlPinYin
            .Apply
        End With
   
        'Sort rows
    
        .Sort.SortFields.Clear
        .Sort.SortFields.Add2 Key:=rowsRange.Resize(, 1), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        With .Sort
            .SetRange rowsRange
            .Header = xlNo 'xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
   
    End With

End Sub

 

[techgirl]

Thank you very much, that worked.