Multilevel numbering upto 5 level from level and position

[ketul shah]

LEVEL	POSITION	OUTPUT
1	1​	1
2	1​	1.1
2	2​	1.2
2	3​	1.3
2	4​	1.4
3	1​	1.4.1
3	2​	1.4.2
3	3​	1.4.3
3	4​	1.4.4
3	5​	1.4.5
4	1​	1.4.5.1
4	2​	1.4.5.2
4	3​	1.4.5.3
1	2​	2

I have two column of level and its position numbers and need to create formula for output column as shown above.

 

[Jeffrey Mahoney]

Please tell us how the Output relates to those two columns. I'm not getting the logic

 

[Eric W]

How about:

Book3
	A	B	C	D
1	LEVEL	POSITION	OUTPUT - v1	OUTPUT - v2
2	1	1	1	1
3	2	1	1.1	1.1
4	2	2	1.2	1.2
5	2	3	1.3	1.3
6	2	4	1.4	1.4
7	3	1	1.4.1	1.4.1
8	3	2	1.4.2	1.4.2
9	3	3	1.4.3	1.4.3
10	3	4	1.4.4	1.4.4
11	3	5	1.4.5	1.4.5
12	4	1	1.4.5.1	1.4.5.1
13	4	2	1.4.5.2	1.4.5.2
14	4	3	1.4.5.3	1.4.5.3
15	1	2	2	2
Sheet1

Cell Formulas
Range	Formula
C3:C15	C3	=LET(p,".",s,SEQUENCE(10),levs,TRIM(MID(SUBSTITUTE(C2,p,REPT(" ",99)),s*99-98,99)),r,IFS(s<A3,levs,s=A3,B3,1,""),TEXTJOIN(p,1,r))
D3:D15	D3	=LET(p,".",s,SEQUENCE(10),levs,TRIM(MID(SUBSTITUTE(D2,p,REPT(" ",99)),s*99-98,99)),r,IFS(s<A3,levs,s=A3,(0&levs)+1,1,""),TEXTJOIN(p,1,r))

The C formula uses the value from column B, the D formula just increments the level from the row above by 1.

 

[ketul shah]

How about:

Book3
	A	B	C	D
1	LEVEL	POSITION	OUTPUT - v1	OUTPUT - v2
2	1	1	1	1
3	2	1	1.1	1.1
4	2	2	1.2	1.2
5	2	3	1.3	1.3
6	2	4	1.4	1.4
7	3	1	1.4.1	1.4.1
8	3	2	1.4.2	1.4.2
9	3	3	1.4.3	1.4.3
10	3	4	1.4.4	1.4.4
11	3	5	1.4.5	1.4.5
12	4	1	1.4.5.1	1.4.5.1
13	4	2	1.4.5.2	1.4.5.2
14	4	3	1.4.5.3	1.4.5.3
15	1	2	2	2
Sheet1

Cell Formulas
Range	Formula
C3:C15	C3	=LET(p,".",s,SEQUENCE(10),levs,TRIM(MID(SUBSTITUTE(C2,p,REPT(" ",99)),s*99-98,99)),r,IFS(s<A3,levs,s=A3,B3,1,""),TEXTJOIN(p,1,r))
D3:D15	D3	=LET(p,".",s,SEQUENCE(10),levs,TRIM(MID(SUBSTITUTE(D2,p,REPT(" ",99)),s*99-98,99)),r,IFS(s<A3,levs,s=A3,(0&levs)+1,1,""),TEXTJOIN(p,1,r))

The C formula uses the value from column B, the D formula just increments the level from the row above by 1.

Thank you Eric for solution.
I would go with solution show in column C as sometimes position number are skipped in between.

My question: does formula in column C work if position number is >100 ?

 

[Eric W]

It does.