msgbox when only one cell is altered?

[AwesomeSteph]

I am struggling with VBA to only display a message box when one cell is altered. What I have works but then if any other cell changes the msgbox continues to prompt the user. please help, this is tool I built for many users and I only want the msgbox to appear when B12 on sheet 1 has anything in it not when any other cell is touched multiple users will be going into the workbooks and I only want the initial person filling it out to be prompted.

Private Sub Worksheet_Change(ByVal Target As Range)
Application.ScreenUpdating = False

Dim MsgTitle, MsgPrompt As String, Ret As Integer
MsgPrompt = "Is this either a New Task or a Technical Change?"
MsgTitle = "Possible Review Required"
If Sheets(1).[B12].Value <> "" Then
       Ret = MsgBox(MsgPrompt, vbYesNo, MsgTitle)
        
    End If
If Ret = vbNo Then
Sheets(8).Activate
MsgBox "Check (Review Not Required) Boxes on lines 1 and 2 on xxx Form"
End If
If Ret = vbYes Then
MsgBox "Ensure Form is included with deliverable"
End If
Application.ScreenUpdating = True
End Sub

 

[Rick Rothstein]

See if this works (note that I restructured your code slightly)...

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim MsgTitle, MsgPrompt As String, Ret As Integer
  If Not Intersect(Target, Range("B12")) Is Nothing Then
    Application.ScreenUpdating = False
    MsgPrompt = "Is this either a New Task or a Technical Change?"
    MsgTitle = "Possible Review Required"
    If Sheets(1).[B12].Value <> "" Then
      Ret = MsgBox(MsgPrompt, vbYesNo, MsgTitle)
      If Ret = vbNo Then
        Sheets(8).Activate
        MsgBox "Check (Review Not Required) Boxes on lines 1 and 2 on xxx Form"
      Else
        MsgBox "Ensure Form is included with deliverable"
      End If
    End If
    Application.ScreenUpdating = True
  End If
End Sub

 

[AwesomeSteph]

Oh man, thank you so much! worked perfect!